# Maintainer: moostik <mooostik_at_gmail.com>
# Contributor: Blaž Tomažič <blaz.tomazic@gmail.com>

pkgname=python-orange
pkgver=2.5a2
pkgrel=1
pkgdesc="Open source data visualization and analysis for novice and experts. Data mining through visual programming or Python scripting."
arch=('i686' 'x86_64')
url="http://www.ailab.si/orange"
license=('GPL')
depends=('python2' 'python2-numpy' 'python-numarray' 'python-numeric' 'python2-matplotlib')
optdepends=('pyqwt: GUI support' 'python-networkx: Network module')
conflicts=('python-orange-hg')
source=("http://pypi.python.org/packages/source/O/Orange/Orange-${pkgver}.tar.gz")
md5sums=('055c68245c7bb3eb3c096f23917d71b8')

build() {
  cd "${srcdir}/Orange-$pkgver"
  python2 setup.py build || return 1
}

package() {
  cd "${srcdir}/Orange-$pkgver"
  python2 setup.py install --root="${pkgdir}" || return 1

  find ${pkgdir} -name '*.py' | while read FILE; do
    sed -i -e "s|#![ ]*/usr/bin/python$|#!/usr/bin/python2|" \
           -e "s|#![ ]*/usr/bin/env python$|#!/usr/bin/env python2|" \
           -e "s|#![ ]*/bin/env python$|#!/usr/bin/env python2|" \
        "$FILE"
  done
}

# vim:set ts=2 sw=2 et: