# Maintainer: Ner0
# Contributor: CReimer

pkgname=nemo-fm
pkgver=1.1.2
pkgrel=1
pkgdesc="Cinnamon file manager (Nautilus fork), stable version"
arch=('i686' 'x86_64')
url="https://github.com/linuxmint/nemo"
license=('GPL2')
depends=('desktop-file-utils' 'exempi' 'gnome-desktop' 'hicolor-icon-theme' 'libexif' 'libnotify' 'libtracker-sparql')
makedepends=('gtk-doc' 'gnome-common' 'gobject-introspection' 'intltool')
optdepends=('gksu: Open as Root'
            'gnome-terminal: Open in Terminal')
conflicts=('nemo-git')
provides=('nautilus')
options=('!emptydirs' '!libtool')
install=nemo.install
source=("$pkgname-$pkgver.tar.gz::https://github.com/linuxmint/nemo/tarball/$pkgver")
md5sums=('6f432bd9277a597a295ac22475d4a12e')

build() {
  cd linuxmint-nemo-*

  ## Set "Open in Terminal" to default terminal (Arch doesn't use x-terminal-emulator)
  #sed -i "s/x-terminal-emulator/gnome-terminal/" src/nemo-view.c

  ./autogen.sh --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --disable-static \
      --libexecdir=/usr/lib/nemo \
      --disable-update-mimedb \
      --disable-gtk-doc-html \
      --disable-schemas-compile
  make
}

package() {
  cd linuxmint-nemo-*
  make DESTDIR="$pkgdir/" install
}