# Maintainer: YOU <you@everywhere.com>

pkgname=blender-addons-yafaray-git
pkgver=20110415
pkgrel=1
pkgdesc="Raytracing open source render engine"
arch=('i686' 'x86_64')
url="http://www.yafaray.org/"
license=('LGPL2.1')

depends=('libxml2' 'openexr' 'libjpeg' 'libpng' 'freetype2' 'libtiff' 'python')
makedepends=('cmake' 'swig' 'git')

provides=('yafaray')
conflicts=('yafaray')

_gitroot=git://github.com/YafaRay/Core.git
_gitname=yafaray
_gitrootexport=git://github.com/YafaRay/Blender-2.5-Exporter.git
_gitnameexport=exporter
_slot="2.59"

build() {
  cd ${srcdir}
  msg "Connecting to GIT server...."

  # core
  if [[ -d "${_gitname}" ]]; then
    cd "${_gitname}" && git pull origin
    cd ..
    msg "The local files are updated."
  else
    git clone "${_gitroot}" "${_gitname}"
  fi
  # exporter
  if [[ -d "${_gitnameexport}" ]]; then
    cd "${_gitnameexport}" && git pull origin
    cd ..
    msg "The local files are updated."
  else
    git clone "${_gitrootexport}" "${_gitnameexport}"
  fi

  msg "GIT checkout done or server timeout"
  msg "Starting build..."

  if [ -e "${srcdir}"/${_gitname}-build ]; then
      rm -rf "${srcdir}"/${_gitname}-build
  fi
  mkdir "${srcdir}/${_gitname}-build"
  cd "${srcdir}/${_gitname}-build"

  cmake \
    -DCMAKE_INSTALL_PREFIX=/usr/share/blender/${_slot}/scripts/addons/yafaray \
    -DYAF_BINDINGS_PY_DIR=/usr/share/blender/${_slot}/scripts/addons/yafaray/bin \
    -DWITH_QT=OFF \
    -DBUILDRELEASE=ON \
    -DYAF_LIB_DIR=bin \
    -DYAF_PY_VERSION=3.2 \
    "../${_gitname}"

  make $MAKEFLAGS
}

package() {
  cd "${srcdir}/${_gitname}-build"

  # Install
  make DESTDIR=${pkgdir} install

  # Install plugins
  mv ${pkgdir}/usr/share/blender/${_slot}/scripts/addons/yafaray/bin/yafaray \
     ${pkgdir}/usr/share/blender/${_slot}/scripts/addons/yafaray/bin/plugins

  # install Exporter
  cd "${srcdir}/${_gitnameexport}"
  git checkout-index -a -f --prefix="${pkgdir}/usr/share/blender/${_slot}/scripts/addons/yafaray/"

  # Compile all .py
  python -m compileall "${pkgdir}/usr/share/blender"

}