#SingleInstance,force
#persistent
SetBatchLines,-1
SetTitleMatchMode,1
menu,tray,icon,%windir%\system32\stobject.dll,28
#ifWinActive Trim Editor ahk_class #32770
    $LButton::TrimEditor_MouseClickHandler()
    PgDn::TrimEditor_IncPos(24)
    PgUp::TrimEditor_IncPos(-24)
#ifWinActive

TrimEditor_MouseClickHandler()
{
    CoordMode,mouse,relative
    MouseGetPos,mx,my,mw,mctl
    if( mctl != "msctls_trackbar321" )
    {
        sendEvent, % "{" substr(A_ThisHotkey,2) "}"
        return
    }

    MouseGetPos,mx,my,mw,mctl
    ControlGetPos,cx,cy,cw,ch,msctls_trackbar321,A

    SendMessage,TBM_GETPOS:=0x400,0,0,msctls_trackbar321,A
    cpos:=ErrorLevel

    SendMessage,TBM_GETRANGEMIN:=0x401,0,0,msctls_trackbar321,A
    cmin:=ErrorLevel

    SendMessage,TBM_GETRANGEMAX:=0x402,0,0,msctls_trackbar321,A
    cmax:=ErrorLevel

    SendMessage,TBM_SETPOS:=0x405,-1,% newpos>=0 ? newpos : (mx<cx ? 0 : ((mx>cx+cw) ? cmax : round((mx-cx-16)/(cw-32)*(cmax-cmin),0))),msctls_trackbar321,A
    ControlClick,msctls_trackbar321,A,,L
}


TrimEditor_IncPos( step )
{
    SendMessage,TBM_GETPOS:=0x400,0,0,msctls_trackbar321,A
    SendMessage,TBM_SETPOS:=0x405,-1,% ErrorLevel+step,msctls_trackbar321,A
    ControlSend,msctls_trackbar321,% step>0 ? "{Right}" : "{Left}",A
}