zeruel_angel

//------------------------------------------------------------------------------
//
//   Teleportation with Menu [FS] v1.1
//   Designed for SA-MP v0.2.2
//
@@//   Created by zeruel_angel for lorfirewall & http://samp.tilens.com
//
//------------------------------------------------------------------------------
#include <a_samp>
//------------------------------------------------------------------------------
new Menu:Tele;
enum lugar
{
    Nombre[20],
    Costo,
    InteriorID,
    Float:X,
    Float:Y,
    Float:Z
}
new Destinations[7][lugar]=
{
    {"OVAL"     ,50 ,1  ,-1402.6613 ,106.3897   ,1032.2734},
    {"8track"   ,50     ,7  ,-1403.0116 ,-250.4526  ,1043.5341},
    {"KickStart"    ,50 ,14 ,-1420.4277 ,1616.9221  ,1052.5313},
    {"Blood Bowl"   ,50 ,15 ,-1417.8927 ,932.4482   ,1041.5313},
    {"Dirtbike" ,50 ,4  ,-1421.5618 ,-663.8262  ,1059.5569},
    {"Vice"     ,50 ,16 ,-1401.0670 ,1265.3706  ,1039.8672},
    {"NADA"     ,0  ,0  ,0.0        ,0.0        ,15.0}
};
//------------------------------------------------------------------------------
public OnFilterScriptInit()
{
    print("\n--------------------------------------");
    print(" Teleportation with Menu [FS] zeruel_angel");
    print("--------------------------------------\n");
    Tele = CreateMenu("Tele",2,25.0,150.0,100.0,100.0);
    SetMenuColumnHeader(Tele, 0, "Destino");
    SetMenuColumnHeader(Tele, 1, "$$$$");
    new aux[10];
    for (new i=0;i<7;i++)
    {
        AddMenuItem(Tele,0,Destinations[i][Nombre]);
        format(aux,10,"%d",Destinations[i][Costo]);
        AddMenuItem(Tele,1,aux);
    }
    AddMenuItem(Tele,0,"Salir");
    AddMenuItem(Tele,1," ");

    return 1;
}
//------------------------------------------------------------------------------
public OnFilterScriptExit()
{
    return 1;
}
//------------------------------------------------------------------------------
public OnPlayerCommandText(playerid, cmdtext[])
{
    if  (strcmp("/Tmenu", cmdtext, true) == 0)
    {
        ShowMenuForPlayer(Tele,playerid);
        TogglePlayerControllable(playerid, false);
        return 1;
    }
    return 0;
}
//------------------------------------------------------------------------------
public OnPlayerSelectedMenuRow(playerid, row)
{
    new Menu:Current = GetPlayerMenu(playerid);
    if  (Current == Tele)
    {
        TogglePlayerControllable(playerid, true);
        if (row==7)
        {
            HideMenuForPlayer(Tele,playerid);
            return 1;
        }
        SetPlayerInterior(playerid,Destinations[row][InteriorID]);
        if (IsPlayerInAnyVehicle(playerid))
        {
            SetVehiclePos(GetPlayerVehicleID(playerid),Destinations[row][X],Destinations[row][Y],Destinations[row][Z]);
        }
        else
        {
            SetPlayerPos(playerid,Destinations[row][X],Destinations[row][Y],Destinations[row][Z]);
        }
        SetCameraBehindPlayer(playerid);
        GivePlayerMoney(playerid,0 - Destinations[row][Costo]);
        return 1;
    }
    return 1;
}
//------------------------------------------------------------------------------
public OnPlayerExitedMenu(playerid)
{
    TogglePlayerControllable(playerid,true);
    return 1;
}