jib

# Contributor: JIN Xiao-Yong <jinxiaoyong@gmail.com>
# Contributor: jib <jbc.as (AT) free.fr>

pkgname=freetype2-infinality
pkgver=2.4.4
pkgrel=2
pkgdesc="TrueType font rendering library with infinality patch"
arch=(i686 x86_64)
license=('GPL')
url="http://freetype.sourceforge.net"
depends=('zlib')
conflicts=('freetype2')
provides=("freetype2=$pkgver")
options=('!libtool')
source=(http://downloads.sourceforge.net/sourceforge/freetype/freetype-${pkgver}.tar.bz2
        http://perso.orange.fr/jbco/dl/freetype-2.2.1-enable-valid.patch
        http://www.infinality.net/files/freetype-add-subpixel-hinting-infinality-20101114-1.patch
        http://www.infinality.net/files/freetype-enable-subpixel-hinting-infinality-20100909-1.patch
        http://www.infinality.net/files/freetype-entire-infinality-patchset-20101114-1.patch
        http://perso.orange.fr/jbco/dl/freetype-2.4.3-20101114-infinality-apply-env-defaults.patch)

build() {
  cd "${srcdir}/freetype-${pkgver}"
  local patch_file
  for patch_file in "${source[@]:2}"; do
      patch -Np1 -i "${srcdir}/${patch_file##*/}"
  done
  sed -i -r 's:.*(#.*SYSTEM_ZLIB.*) .*:\1:' ${srcdir}/freetype-2.4.4/include/freetype/config/ftoption.h

  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/freetype-${pkgver}"

  make DESTDIR="${pkgdir}" install
}

md5sums=('b3e2b6e2f1c3e0dffa1fd2a0f848b671'
         '214119610444c9b02766ccee5e220680'
         '799a2d229c2997a5bb2d5b7c9f92fdba'
         'a88b1a66da44a90c1fdcdeaa39a2dc09'
         '6725774b17820f5413cb6a3cf7547f53'
         'edfd12844a8717615e36da060ad78381')