Shynd

#include "WoWAmeliorator.au3"

_BMInitialize()

Global $hWnd = WinGetHandle("World of Warcraft")
If @error Or $hWnd = 0 Then
    MsgBox(0x10, "Window Not Found", "Could not find World of Warcraft game window.")
    Exit
EndIf

Global $hProcess = _BMOpenProcess($hWnd, False)
If @error Or $hProcess = 0 Then
    MsgBox(0x10, "OpenProcess Error", "Could not open process for read/write.")
    Exit
EndIf

Global $ObjectManager = 0
Global $CurObject = 0, $NextObject = 0
Global $PlayerGUID, $CurGUID
Global $CurName, $CreatedBy
Global $NumObjects = 0, $CurOutputString = ""

While $ObjectManager = 0
    $ObjectManager = _WoWGetObjManager($hProcess)

    If $ObjectManager = 0 Then
        Sleep(100)
    EndIf
WEnd

While $CurObject = 0
    $CurObject = _WoWGetFirstObject($hProcess, $ObjectManager)

    If $CurObject = 0 Then
        Sleep(100)
    EndIf
WEnd

$PlayerGUID = _WoWGetLocalGUID($hProcess)

ConsoleWrite(StringFormat("Player GUID: 0x%08X", $PlayerGUID) & @CR)

;--------------------------------------------------
; OBJECT DUMP LOOP
;--------------------------------------------------
ConsoleWrite(@CR & "WoW AutoIt Object Dump" & @CR)

While ($CurObject <> 0 And BitAND($CurObject, 1) = 0)
    $NumObjects += 1

    $CurGUID = _WoWGetObjectGUID($hProcess, $CurObject)
    $CurType = _WoWGetObjectType($hProcess, $CurObject)

    $CurOutputString = StringFormat("% 3i: 0x%08X | %13s | %s", $NumObjects, $CurGUID, _WoWGetTypeString($CurType), _WoWGetName($hProcess, $CurObject))

    If $CurType = $OT_GameObject Then
        $CreatedBy = _WoWGetKnownField($hProcess, $CurObject, $OBJECT_FIELD_CREATED_BY)
        If $CreatedBy <> 0 Then
            $CurOutputString &= StringFormat(" | Created By: 0x%08X", $CreatedBy)
            If $CreatedBy = $PlayerGUID Then
                $CurOutputString &= " -- THIS OBJECT WAS CREATED BY YOUR PLAYER (Fishing Bobber?)"
            EndIf
        EndIf
    EndIf

    If $CurGUID = $PlayerGUID Then
        $CurOutputString &= " <<<<<<<<<< YOU"
    EndIf

    ConsoleWrite($CurOutputString & @CR)

    $CurObject = _WoWGetNextObject($hProcess, $CurObject)
WEnd

_BMCloseHandle($hProcess)
_BMDispose()