# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
# Contributor: Martin Erik Werner ("arand") <martinerikwerner@gmail.com>

pkgname=redeclipse
pkgver=1.4
pkgrel=1
pkgdesc="A single-player and multi-player first-person ego-shooter, built as a total conversion of Cube Engine 2"
arch=('i686' 'x86_64')
url="http://redeclipse.net"
license=('custom' 'CCPL' 'ZLIB' 'MIT')
depends=('sdl_image'  'libgl' 'sdl_mixer' 'hicolor-icon-theme')
makedepends=('mesa' 'imagemagick')
install=redeclipse.install
source=(http://downloads.sourceforge.net/${pkgname}/${pkgname}_${pkgver}_nix.tar.bz2)

build() {
    cd "$srcdir/$pkgname-$pkgver/src"
    make
}

package() {
    cd "$srcdir/$pkgname-$pkgver"

    make -C src DESTDIR="$pkgdir" prefix=/usr system-install

    chown -R root:games "$pkgdir/usr/"{share,lib}"/redeclipse"
    chmod -R o-rwx "$pkgdir/usr/lib/redeclipse"
    find "$pkgdir/usr/share/redeclipse" -type d -exec chmod 750 {} \;
    find "$pkgdir/usr/share/redeclipse" -type f -exec chmod 640 {} \;

    #install -Dm644 license.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    #install -Dm644 trademark.txt "$pkgdir/usr/share/licenses/$pkgname/TRADEMARK"
}

sha256sums=('a0dfc527b0f437170a423b55df68a97e1b6e60d8c9fb6c842519b6670c1e69bf')