Untitled

# Contributor: JIN Xiao-Yong <jinxiaoyong@gmail.com>

## Change the following value to "y" if you're using a US locale:
_I_USE_DOT_DELIMITERS="n"

pkgname=freetype2-infinality
pkgver=2.4.3
pkgrel=7
pkgdesc="TrueType font rendering library with infinality patch"
arch=(i686 x86_64)
license=('GPL')
url="http://freetype.sourceforge.net"
depends=('zlib')
conflicts=('freetype2')
provides=("freetype2=$pkgver")
options=('!libtool')
source=(http://downloads.sourceforge.net/sourceforge/freetype/freetype-${pkgver}.tar.bz2
        http://www.infinality.net/files/infinality-settings
        http://www.infinality.net/files/freetype-filter-envvar-fix-20101117-1.patch
        freetype-2.2.1-enable-valid.patch
        http://www.infinality.net/files/freetype-add-subpixel-hinting-infinality-20101114-1.patch
        http://www.infinality.net/files/freetype-enable-subpixel-hinting-infinality-20100909-1.patch
        http://www.infinality.net/files/freetype-entire-infinality-patchset-20101114-1.patch)

build() {
  cd "${srcdir}/freetype-${pkgver}"
  local patch_file
  for patch_file in "${source[@]:3}"; do
      patch -Np1 -i "${srcdir}/${patch_file##*/}"
  done

  # Apply fix for non-US locales
  if [ "$_I_USE_DOT_DELIMITERS" = "n" ]; then
      patch -Np1 -i "${srcdir}/freetype-filter-envvar-fix-20101117-1.patch"
  fi

  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/freetype-${pkgver}"

  make DESTDIR="${pkgdir}" install
  install -D -T "${srcdir}/infinality-settings" "${pkgdir}/etc/profile.d/infinality-settings.sh"
}

md5sums=('75ac7082bde7b3805dc5d6bc806fa045'
         'd006394c6e3325cc4d9196024a123a80'
         '93b176239447f2623d76439a08d598da'
         '214119610444c9b02766ccee5e220680'
         '799a2d229c2997a5bb2d5b7c9f92fdba'
         'a88b1a66da44a90c1fdcdeaa39a2dc09'
         '6725774b17820f5413cb6a3cf7547f53')