[KUPFER] By SpepS

# Maintainer: D. Can Celasun <dcelasun[at]gmail[dot]com>
# Contributor: Asa Marco <marcoasa90[at]gmail[.]com>
# Contributor: SpepS <dreamspepser at yahoo dot it>

pkgname=kupfer
pkgver=v202
pkgrel=4
pkgdesc="Launcher application written in python. Similar to Gnome-Do / Launchy"
arch=('any')
url="http://kaizer.se/wiki/kupfer/"
license=('GPL')
depends=('pyxdg' 'pygtk' 'dbus-python'  'python-keybinder' 'python-keyring'
         'hicolor-icon-theme' 'shared-mime-info')
optdepends=('gnome-python-desktop: enables all plugins and gnome integration'
            'python-wnck: tracks running applications'
            'realpath: nautilus integration')
makedepends=('intltool')
source=(http://kaizer.se/publicfiles/kupfer/$pkgname-$pkgver.tar.gz)
md5sums=('461a43cc0d23b4490fa0c2166a64c0ab')
install=kupfer.install

build() {

  cd "$srcdir/$pkgname-$pkgver"

  export PYTHON="/usr/bin/python2"

  sed \
	-e "s_env python_&2_" \
	-e "s_bin/python_&2_" \
	-i `grep -rlE "(env python|bin/python)" .`

  ./waf configure --prefix=/usr
  ./waf
}

package() {

  cd "$srcdir/$pkgname-$pkgver"

  ./waf install -f --destdir="$pkgdir"
}