pcwUnstick PL

' pcwUnstick_pl.vbs
''''''''''''''''''''''''''''''''''''''''''''''''
' Tutaj możesz ustalić plik do odtworzenia
' Ustaw oddzielny plik WAV.
' Przykład: "C:\Windows\Media\ding.wav"
''''''''''''''''''''''''''''''''''''''''''''''''

soundfile = ""

''''''''''''''''''''''''''''''''''''''''''''''''
' Tutaj zaczyna się skrypt:
''''''''''''''''''''''''''''''''''''''''''''''''

strMsg = ""
strComputer = "."

Set objWMI = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colDiskDrives = objWMI.ExecQuery("Select DeviceID from Win32_DiskDrive WHERE InterfaceType='USB'")
For Each objDiskDrive In colDiskDrives
    Set colDiskPartitions = objWMI.ExecQuery("ASSOCIATORS OF {Win32_DiskDrive.DeviceID=""" & Replace(objDiskDrive.DeviceID, "\", "\\") & """} WHERE AssocClass = Win32_DiskDriveToDiskPartition")
    For Each objDiskPartition In colDiskPartitions
        Set colLogicalDisks = objWMI.ExecQuery("ASSOCIATORS OF {Win32_DiskPartition.DeviceID=""" & objDiskPartition.DeviceID & """} WHERE " & "AssocClass = Win32_LogicalDiskToPartition")
        For Each objLogicalDisk In colLogicalDisks
            if strUSBDrive = "" then
                strUSBDrive = objLogicalDisk.DeviceID
            else
                strUSBDrive = strUSBDrive & " i " & objLogicalDisk.DeviceID
            end if
        Next
    Next
Next

Set objWMI = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colDiskDrives = objWMI.ExecQuery("Select DeviceID from Win32_DiskDrive WHERE InterfaceType='1394'")
For Each objDiskDrive In colDiskDrives
    Set colDiskPartitions = objWMI.ExecQuery("ASSOCIATORS OF {Win32_DiskDrive.DeviceID=""" & Replace(objDiskDrive.DeviceID, "\", "\\") & """} WHERE AssocClass = Win32_DiskDriveToDiskPartition")
    For Each objDiskPartition In colDiskPartitions
        Set colLogicalDisks = objWMI.ExecQuery("ASSOCIATORS OF {Win32_DiskPartition.DeviceID=""" & objDiskPartition.DeviceID & """} WHERE " & "AssocClass = Win32_LogicalDiskToPartition")
        For Each objLogicalDisk In colLogicalDisks
            if str1394Drive = "" then
                str1394Drive = objLogicalDisk.DeviceID
            else
                str1394Drive = str1394Drive & " i " & objLogicalDisk.DeviceID
            end if
        Next
    Next
Next

if strUSBDrive <> "" then
    strMsg = "Nie zapomnij nośnika(ów) USB: " & strUSBDrive & chr(10)
end if

if str1394Drive <> "" then
    strMsg = strMsg & "Nie zapomnij nośnika(ów) Firewire: " & str1394Drive
end if

if strMsg <> "" then
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set objWSH = CreateObject("Wscript.Shell")
    if soundfile = "" then soundfile = objWSH.ExpandEnvironmentStrings("%WINDIR%") & "\Media\_Ringin.wav"
    if fso.FileExists(soundfile) then objWSH.Run "sndrec32.exe /play /close " & soundfile, 0, false
    Msgbox strMsg, 16, "External Removable Media found!"
end if