buildscript {
    repositories {
        jcenter()
        mavenCentral()
        maven {
            url 'https://plugins.gradle.org/m2/'
        }
    }

    dependencies {
        classpath 'com.github.jengelman.gradle.plugins:shadow:1.2.3'
    }
}

group 'com.favorlock'
version '1.0-SNAPSHOT'

apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'com.github.johnrengelman.shadow'
apply plugin: 'idea'

sourceCompatibility = 1.8
targetCompatibility = 1.8

ext {
    atomix = '1.0.0-rc9'
    paperspigot = '1.10.2'
    bungeecord = '1.10-SNAPSHOT'
}

repositories {
    mavenLocal()
    mavenCentral()
    maven {
        name = 'theminecoder'
        url = 'http://maventemp.theminecoder.me/'
    }
    maven {
        name = 'sonatype'
        url = 'https://oss.sonatype.org/content/groups/public'
    }
}

dependencies {
    compile group: 'io.atomix', name: 'atomix-all', version: atomix
    compile group: 'org.paperspigot', name: "paperspigot-$paperspigot", version: paperspigot
    compile (group: 'net.md-5', name: 'bungeecord-api', version: bungeecord) {
        exclude group: 'io.netty'
        exclude group: 'net.sf.trove4j'
        exclude group: 'org.yaml'
    }
    testCompile group: 'junit', name: 'junit', version: '4.11'
}

shadowJar {
    dependencies {
        exclude(dependency('.*:guava'))
        exclude(dependency('com.google.code.gson:gson'))
        exclude(dependency('org.paperspigot:.*'))
        exclude(dependency('org.immutables:value'))
        exclude(dependency('org.immutables:builder'))
        exclude(dependency('.*:log4j-core'))
        exclude(dependency('net.md-5:.*'))
    }

    relocate 'io.netty', 'com.favorlock.shaded.netty'
    relocate 'io.atomix', 'com.favorlock.shaded.atomix'
}