Untitled

# Maintainer: Heiko Baums <heiko at baums-on-web dot de>
# Contributor: Kurt J. Bosch <kjb-temp-2009 at alpenjodel dot de>

pkgname=fbsplash
pkgver=1.5.4.3
pkgrel=31
pkgdesc="A userspace implementation of a splash screen for Linux (formerly known as gensplash)"
arch=('i686' 'x86_64')
url="http://fbsplash.berlios.de"
license=('GPL')
depends=('miscsplashutils' 'freetype2' 'libjpeg' 'libpng' 'libmng' 'lcms' 'gpm')
optdepends=('kernel26-fbcondecor: enable console background images'
            'initscripts-extras-fbsplash: boot/shutdown with fbsplash'
            'uswsusp-fbsplash: suspend to disk with fbsplash'
            'python: convert themes from splashy to fbsplash')
backup=(
  'etc/splash/splash'
  'etc/conf.d/splash'
)
options=('!makeflags')
install=fbsplash.install
source=(
  http://dev.gentoo.org/~spock/projects/gensplash/archive/splashutils-${pkgver}.tar.bz2
  fbsplash.git.patch
  splash.conf
  fbsplash.initcpio_install
  fbsplash.initcpio_hook
  fbcondecor.conf
  fbcondecor.daemon
)
md5sums=('c722cd4148817b9c50381d9bdc1ea6ef'
         '3a338c60ed0710c8b7e3e08929db521a'
         '61025cc947975c3b3a705d086250dcff'
         '249b4ad977235242d2b1b9cc6e1b6254'
         'dbc9aa259cb6bdd19f361ffd1cd5e32a'
         'b3db9d4fd902b62ac9e38589677e2d16'
         '715926469d05eecd345c052e6248ca32'
)
build() {
  cd ${srcdir}/splashutils-${pkgver}

  # patch for building splashutils with glibc and dynamical linking
  patch -Np0 -i ${srcdir}/fbsplash.git.patch || return 1
  autoreconf

  # fix fbcondecor_ctl splash type
  sed -e 's,fbsplash_lib_init(fbspl_bootup),fbsplash_lib_init(fbspl_undef),' -i src/fbcon_decor_ctl.c

  ./configure --prefix=/usr --sysconfdir=/etc --without-klibc --enable-fbcondecor --with-gpm --with-mng --with-png --with-ttf --with-ttf-kernel || return 1
  make || return 1
  make DESTDIR=${startdir}/pkg install || return 1

  cd ${pkgdir}

  # fix duplicate slashes to get splash_cache_cleanup grep to work
  sed -r -e 's,^(export spl_.*="/)/+,\1,' -i sbin/splash-functions.sh

  # fix the path to splash_util
  sed -r -e 's,^(export spl_util=)\"/bin/,\1"/sbin/,' -i sbin/splash-functions.sh

  # provide the mountpoints needed by splash-functions.sh
  mkdir -p lib/splash/{cache,tmp}

  # Install the config file
  #install -D -m644 ${srcdir}/splash.conf etc/splash/splash || return 1
  install -D -m644 ${srcdir}/splash.conf etc/conf.d/splash || return 1

  # Install initcpio hook
  install -D -m644 ${srcdir}/fbsplash.initcpio_install lib/initcpio/install/fbsplash &&
  install -D -m644 ${srcdir}/fbsplash.initcpio_hook    lib/initcpio/hooks/fbsplash   || return 1

  # Install the fbcondecor daemon script and config file
  install -D -m644 ${srcdir}/fbcondecor.conf   etc/conf.d/fbcondecor &&
  install -D -m755 ${srcdir}/fbcondecor.daemon etc/rc.d/fbcondecor   || return 1
}