params ["_respawn", "_mkr", "_index"];

_pl = selectRandom allplayers;
_roads = _pl nearRoads 500;
_roads = _roads apply {[_x distance _pl, _x]};

if (count babe_coop_cars > 0) then
{
	_roads = _roads select
	{
		_roadA = _x;
		{(_roadA select 1) distance (_x select 0) < 200} count babe_coop_cars == 0
	};
};

_roads sort false;

_road = _roads select 0 select 1;


_carpos = getpos _road;
_car = createVehicle [selectRandom all_civcars, _carpos, [], 0, 'can_collide'];

_car setDir ([_car, _pl] call BIS_fnc_dirTo);

_driver = (createGroup civilian) createUnit [selectRandom all_civs, getpos _car, [], 0, "FORM"];
{_driver disableAI _x} foreach ["FSM","AIMINGERROR","SUPPRESSION","AUTOTARGET","TARGET","COVER","SUPPRESSION","AUTOCOMBAT","CHECKVISIBLE"];
_driver setCombatMode "BLUE";
_driver setBehaviour "CARELESS";

_driver assignAsDriver _car;
_driver moveInDriver _car;

_wtm = _pl worldToModel getpos _car;
_targetPos = _pl modelToWorld [(_wtm select 0) * -2, (_wtm select 1) * -2, 0];
_targetRoads = _targetPos nearRoads 2000;
_targetRoads = _targetRoads apply {[_x distance _targetPos, _x]};
_targetRoads sort true;
_targetPos = getpos (_targetRoads select 0 select 1);

if (isNil "_targetPos") then
{
	_targetPos = _carpos;
};




_driver moveTo _targetpos;

if (babe_coop_debug && !_respawn) then
{
	_mkr = createMarker [str _car, getpos _car];
	_mkr setMarkerShape "ELLIPSE";
	_mkr setMarkerBrush "Solid";
	_mkr setMarkerSize [10,10];
	_mkr setMarkerColor "ColorBlue";
	_mkr setMarkerAlpha 1;
};
if (!_respawn) then
{
	babe_coop_cars pushback [_car, _driver, _mkr, _targetPos, time, time];
} else
{
	babe_coop_cars set [_index, [_car, _driver, _mkr, _targetPos, time, time]];
};