qgis-2.6.0 PKGBUILD

pkgname=qgis
pkgver=2.6.0
pkgrel=1
pkgdesc='Quantum GIS is a Geographic Information System (GIS) that supports vector, raster & database formats'
url='http://qgis.org/'
license=('GPL')
arch=('i686' 'x86_64')
depends=('qt4>=4.8.6'
         'proj>=4.8.0'
         'geos>=3.4.2'
         'sqlite>=3.8.5'
         'gdal>=1.11.0'
         'expat>=2.1.0'
         'qwt>=6.1.0'
         'qwtpolar>=1.1.0'
         'python2'
         'python2-pyqt4>=4.11.2'
         'python2-qscintilla>=2.8.4'
         'python2-sip>=4.16.3'
         'python2-psycopg2'
         'python2-pygments'
         'python2-dateutil'
         'python2-jinja'
         'python2-markupsafe'
         'python2-pytz'
         'libspatialite>=4.2.0'
         'spatialindex>=1.8.0')
makedepends=('cmake'
             'flex'
             'bison'
             'txt2tags'
             'perl')
optdepends=('grass: GRASS plugin support'           # Uncomment relevant cmake option in build() below
            'fcgi: QGIS Map Server support'         # if you want GRASS, QGIS Map Server
            'osgearth: QGIS Globe plugin support'   # or the Globe Plugin enabled
            'gsl: Georeferencing plugin support'
            'gpsbabel: GPS toolbar support')
provides=("$pkgname=$pkgver")
conflicts=("$pkgname-git" "$pkgname")
install="$pkgname.install"
source=("http://qgis.org/downloads/qgis-latest.tar.bz2")
md5sums=('5540e0648caf261a264c2370be484163')

prepare() {
   cd "$srcdir/$pkgname-$pkgver"
#   mv "$srcdir/FindPyQt.py" cmake/                  # https://hub.qgis.org/issues/10596

   # http://www.uclmail.net/users/babayoshihiko/fink/qgis/pyqt4-sip/index.html
   # perl -pi -e "s|from PyQt4 import pyqtconfig||" python/console/console.py
   # perl -pi -e "s|pyqtconfig\.Configuration\(\)\.qt_version >= 0x40700|True|" python/console/console.py

  # Fixing by hand shebang for .py files.
  find . -iname '*.py' | xargs sed -ie 's:^#!/usr/bin/env python$:#!/usr/bin/env python2:'
  find . -iname '*.py' | xargs sed -ie 's:^#!/usr/bin/python$:#!/usr/bin/env python2:'
}

build() {
  # Fix insecure RPATH is weird, but just works ;)
  # echo "os.system(\"sed -i '/^LFLAGS/s|-Wl,-rpath,.\+ ||g' gui/Makefile core/Makefile\")" >> python/configure.py.in

  cd "$srcdir/$pkgname-$pkgver"

  if [ -d build ]; then
    rm -rf build
  fi
  mkdir build
  cd build

  cmake ../ \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_SKIP_RPATH=ON \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DENABLE_TESTS=OFF \
    -DQGIS_MANUAL_SUBDIR=share/man \
    -DPYTHON_EXECUTABLE=/usr/bin/python2 \
    -DPYTHON_LIBRARY=/usr/lib/libpython2.7.so \
    -DPYTHON_INCLUDE_PATH=/usr/include/python2.7 \
    -DPYTHON_SITE_PACKAGES_DIR=/usr/lib/python2.7/site-packages \
    -DQT_QMAKE_EXECUTABLE=/usr/bin/qmake-qt4 \
    -DWITH_INTERNAL_QWTPOLAR=OFF \
    -DWITH_INTERNAL_SPATIALITE=OFF \
#    -DWITH_MAPSERVER=TRUE \
#    -DWITH_GRASS=ON \
#    -DGRASS_PREFIX=/opt/grass \
#    -DGRASS_INCLUDE_DIR=/opt/grass/include/ \
#    -DWITH_GLOBE=TRUE \

  make

  # TODO: fix $srcdir warning if it's a real problem...

}

package() {
  cd "$srcdir/$pkgname-$pkgver/build"

  make DESTDIR="$pkgdir/" install

  # install some freedesktop.org compatibility
  install -D -m644 "$srcdir/$pkgname-$pkgver/debian/qgis.desktop" \
    "$pkgdir/usr/share/applications/qgis.desktop"
  install -D -m644 "$srcdir/$pkgname-$pkgver/debian/qbrowser.desktop" \
    "$pkgdir/usr/share/applications/qbrowser.desktop"

  # TODO: these aren't working for some reason, ie, .qgs files are not opened by QGIS...
  install -dm755 "$pkgdir/usr/share/pixmaps" \
    "$pkgdir/usr/share/mimelnk/application"
  for mime in "$srcdir/$pkgname-$pkgver/debian/mime/application/"*.desktop
    do install -m644 "$mime" "$pkgdir/usr/share/mimelnk/application"
  done
  ln -s /usr/share/qgis/images/icons/qgis-icon.png "$pkgdir/usr/share/pixmaps/qgis.png"
  ln -s /usr/share/qgis/images/icons/qgis-mime-icon.png "$pkgdir/usr/share/pixmaps/qgis-mime-icon.png"

}