concept: ~adjectifs_inutile (admirable amazing deluxe desirable distinctive elite exceptional extraordinaire fabulous famous fantastic fascinating favorable grand great heavenly impressive infamous ingenious inspiring irresistible lovely luxurious magnificent mighty miraculous ostentatious perfect persuasive popular powerful pretentious prominent remarkable sophisticated special sublime super supreme tremendous versatile wonderful)
concept: ~dieu(god God Goddess goddess god~2 deity religion faith creed cult doctrine sect divinity)
concept: ~sympathique (generous~3 loving~1 caring~2  affectionate cordial benevolent considerate devoted friendly generous thoughtful nice good affable amiable compassionate considerate cool pleasant sweet likable charming fun lovely great peaceful forgive forgiving)
concept: ~antipathique (evil vengeful angry mean~a vicious vindictive hostile avenging implacable punitive rancorous relentless unforgiving spiteful inimical irritable furious jealous)
concept: ~dieux_existants (~mythical_intelligent_being ~greek_gods ~cartoon_character ~mythical_creatures Roman_deity~1 Jesus Yeezus money)
concept: ~adjectifs (~adjectives)

topic: ~god_identity (name ~adjective "god of" ~family_members ~living_properties_adjectives)

u: (_we) ^mark(~dieu _0)  ^repeat() ^keep()
u: (_I) ^mark(~dieu _0)  ^repeat() ^keep()
u: (_he) $dieu_genre = 0 ^mark(~dieu _0)  ^repeat() ^keep()
u: (_his) $dieu_genre = 0 ^mark(~dieu _0)  ^repeat() ^keep()
u: (_she) $dieu_genre = 1 ^mark(~dieu _0)  ^repeat() ^keep()
u: (_her) $dieu_genre = 1 ^mark(~dieu _0)  ^repeat() ^keep()
u: (_$godname?) ^mark(~dieu _0)  ^repeat() ^keep()
u: (~yes) ^mark(yes)  ^repeat() ^keep()
u: (~no) ^mark(no)  ^repeat() ^keep()

u: (["ambarsayz" "sheepsayz"]) ok. ^repeat() ^keep()



#  ----------------------------------------------------------------
#  God's name and gender
#  ----------------------------------------------------------------

s: INTRIGINGNAME (!$godname ~dieu *~2 name *~2 be _*2 > ) '_0? Now that is interesting...
	$godname = ^pos( CAPITALIZE '_0 )
	a:([$godname ~dieux_existants] ~why) Well, the name kinda ring a bell. # ? as Check if the variable is part of concept on the right
	a:(~why) Well, I once had a sheep named $godname.
		CMouton

s: CORRECTNAME (<< not [his her its] name >>) What is its name then?
	a: (%length==1 _*1) '_0 ? There's a nice ring to it.
		$godname = '_0
		b:(~non) Look, a name's just a name. I'll just call it $godname.

	a: (<< ~dieu name>> * be _*2) '_0 ? Never heard of it. # Make sure that was is intercepted is maximum 2 word
		$godname = '_0
		b:(~non) Look, a name's just a name. I'll just call it $godname.

s: CORRECTNAME2 (not * called * $godname?) What is its name then?
	a: (%length==1 _*1) '_0 ? There's a nice ring to it.
		$godname = '_0
		b:(~non) Look, a name's just a name. I'll just call it $godname.

	a: (<< ~dieu name>> * be _*2) '_0 ? Never heard of it. # Make sure that was is intercepted is maximum 2 word
		$godname = '_0
		b:(~non) Look, a name's just a name. I'll just call it $godname.

s: (!$godname _individual~1) Wait, is your God's name '_0 ?
	a:(~oui) Ok.
		$godname = '_0

	a:(<<~non ~dieu name >> be _*1) Sorry, then what is its name?
		b: (~dieu * name * be _*1) '_0 ? Never heard of it.
		$godname = '_0
		b: (_individual~1) '_0 ? Never heard of it.
		$godname = '_0

	a:(~non) Sorry, then what is its name?
		b: (~dieu * name * be _*1) '_0 ? Never heard of it.
		$godname = '_0
		b: (_individual~1) '_0 ? Never heard of it.
		$godname = '_0

t: GODNAME () So, how do you call that God?

# Disable DO_SPELLCHECK for the name
$token = #DO_SUBSTITUTE_SYSTEM   | #DO_NUMBER_MERGE   | #DO_PROPERNAME_MERGE | #DO_POSTAG  | #DO_PARSE

	# Moved this stuff from introductions because it seemed not to be run on the server!
	$personnalite = 0
	$facilite = 0
	$societe = 0
	$cout = 0
	$service = 0
	$egalitaire = 0
	$espoir = 0
	$classe = 0
	$credible = 0
	$symbole = NULL
	$godname = NULL
	$nom_croyants = NULL
	$alea = ^compute(0 random 10)

	if ($alea > 4){
		$$unknownGodNameAdj = ^pick(~physical_properties_adjectives)
		$unknownGodNameAdj  = ^pos( CAPITALIZE $$unknownGodNameAdj )
	}
	if ($alea < 5){
		$$unknownGodNameAdj = ^pick(~psychology_adjectives)
		$unknownGodNameAdj  = ^pos( CAPITALIZE $$unknownGodNameAdj )
	}
	$alea = ^compute(0 random 10)
	if ($alea > 4){
		$unknownGodName = ^pos( CAPITALIZE ^pick(~beings) )
	}
	if ($alea < 5){
		$unknownGodName = ^pos( CAPITALIZE ^pick(~animals) )
	}

	a: (me) ^reuse(~god_identity.JESUISDIEU)

	a: (< I be) ^reuse(~god_identity.JESUISDIEU)

	a: ([~emomisunderstand ~emoignorance]) I'll just call it $unknownGodNameAdj $unknownGodName.
		$godname = ^join(AUTOSPACE $unknownGodNameAdj $unknownGodName)

	a: ([what which] ?) If you're not here to tell me about your recent meeting with some divinity, then you're wasting my time.

	a: (_[~dieux_existants ~movie])
		$godname = ^pos( CAPITALIZE '_0 )
		^reuse(~god_identity.INTRIGINGNAME)


	a: ({~dieu} * [call "name is" named "known as" "referred to" be] _*~3)
		$godname = ^pos( CAPITALIZE '_0 )
		$godname? Never heard of it. ^gambit(~)

	a: (_{[~adjectifs ~determinerlist title~3]} _individual~1) _0 '_1 ? Never heard of it.
		$$fname = ^pos( CAPITALIZE _0 )
		$$lname = ^pos( CAPITALIZE '_1 )
		$godname = ^join(AUTOSPACE $$fname $$lname)
		^gambit(~)

	a: (not * call) That's fair enough, but for the sake of this conversation, I'll refer to it as $unknownGodNameAdj $unknownGodName.
		$godname = ^join(AUTOSPACE $unknownGodNameAdj $unknownGodName)

	a: (%length=1 _*1) '_0 ? Never heard of it.
		$godname = ^pos( CAPITALIZE '_0 )

	a: (%length=2 _*1 _*1)
		$$fname = ^pos( CAPITALIZE '_0 )
		$$lname = ^pos( CAPITALIZE '_1 )
		$godname = ^join(AUTOSPACE $$fname $$lname)
		$godname? Never heard of it. ^gambit(~)
		b:(~non ?) No, never.

	a: (%length=3 _*1 _*1 _*1)
		$$fname = ^pos( CAPITALIZE '_0 )
		$$mname = ^pos( CAPITALIZE '_1 )
		$$lname = ^pos( CAPITALIZE '_2 )
		$godname = ^join(AUTOSPACE $$fname $$mname $$lname)
		^reuse(~god_identity.INTRIGINGNAME)

	a:(_{[title~3 ~adjectives]} _~nounroot)
		$$fname = ^pos( CAPITALIZE '_0 )
		$$lname = ^pos( CAPITALIZE '_1 )
		$godname = ^join(AUTOSPACE $$fname $$lname)
		I like it. It's kind of dignified. ^gambit(~)


s: (<< ~dieu not [have need] name >>) That's fair enough, but for the sake of this conversation, I'll refer to it as $unknownGodNameAdj $unknownGodName.
	$godname = ^join(AUTOSPACE $unknownGodNameAdj $unknownGodName)

s: (!yes << ~non {be} ~dieu name>> ) Yes, that's what I said, $godname!

s: (<   ~non  $godname? {, :} *2 ) Yes, that's what I said, $godname!

s: (%length<=5 <<name  ~non  $godname?>>) Yes, yes, that's what I said: $godname! # Placing ? after a variable allows you to ask if a concept or variable is in the sentence (and not if it is set)
	$godname = $unknownGodName

t: (!$godname) Remind me that God's name again?

t: (!$godname) Since you're being so evasive about your god's name, I'll just call it the $unknownGodNameAdj $unknownGodName.
	$godname = ^join(AUTOSPACE $unknownGodNameAdj $unknownGodName)
	a:(~non) $godname it is.
	a:([exactly just right]) Maybe I should be the prophet.

# Reset $token to nomal (DO_SPELLCHECK)
u: () $token = #DO_SUBSTITUTE_SYSTEM   | #DO_NUMBER_MERGE   | #DO_PROPERNAME_MERGE  | #DO_SPELLCHECK | #DO_POSTAG  | #DO_PARSE
	^gambit(~)



s: ( $godname I be god ) You? You are the ^pick(~adjectifs_inutile) $godname?
	$credible -= 1
	a:(~oui) Can I get something from you then?
		b:(~oui) Can you give me a break? Ah! Come on! I'll just call your god the $unknownGodNameAdj $unknownGodName.
		$godname = ^join(AUTOSPACE $unknownGodNameAdj $unknownGodName)
		b:(~non) Thought so.
	b:(~non) Yeah, I thought so.

s: JESUISDIEU ( !$godname I be *2 god ) You? You are the ^pick(~adjectifs_inutile) god ?
	$credible -= 1
	a:(~oui) Can I get something from you then?
		b:(~oui) Can you give me a break? Ah! Come on! I'll just call your "god" the $unknownGodNameAdj $unknownGodName.
		$godname = ^join(AUTOSPACE $unknownGodNameAdj $unknownGodName)
		b:(~non) Thought so.
	b:(~non) Yeah, I thought so.

s: (!not <<[silly stupid ridiculous dumb idiotic foolish ludicrous]>> name) I know! ^gambit(~)

s: ([he it she his her its] * [name called] _*) Ok, I'll call it '_0 if you prefer.


#  ----------------------------------------------------------------
#  God of ...
#  ----------------------------------------------------------------


s: (~dieu is the '_*) Shall we call it $godname the '_0 ?
	CMouton
	a:(~oui) Classy!
		CPlus
		$titre = ^pos( CAPITALIZE '_0 )
		$godname = ^join($godname the $titre)
		$classe += 1
	a:(~non) It sounded kind of silly.

s: (!not ~dieu * of * _{~adjectifs} _act~1z ) $godname is the God of '_0 '_1?
	CMouton
	a:(~oui) I'll remember next time I have to do that.
		$specialite = '_1
		$dieu_activite = 1
	a:(~non) That would have been unusual!

s: (!not ~dieu * of * _{~adjectifs} _feeling~1z ) $godname is the God of '_0 '_1?
	CMouton
	a:(~oui) Must have a lot of work then.
		$specialite = '_1
		$dieu_emotion = 1
	a:(~non) Yeah, other Gods are already doing that anyways.

s: (!not ~dieu * of * _{~adjectifs} _~role ) $godname is the God of '_0 '_1?
	CMouton
	a:(~oui) I guess those people need a God too!
		$specialite = '_1
		$dieu_role = 1
	a:(~non) I thought that limited the audience a bit.


s: (!not  ~dieu * of * _{~adjectifs} _location~1 ) $godname is the God of '_0 _1?
	CMouton
	a:(~oui) Now that's a vague specialty.
		$specialite = '_1
		$dieu_concept = 1
	a:(~non) Yeah, you don't want such a conceptual God.

s: (!not  ~dieu * of * _{~adjectifs} _animate_thing~1 ) $godname is the God of '_0 '_1?
	CMouton
	a:(~oui) You must like ^pos(NOUN _0 PLURAL) a lot!
		$specialite = '_1
		$dieu_chosevivante = 1
	a:(~non) Yeah, why would ^pos(NOUN _0 PLURAL) need a god?!

s: (!not ~dieu * of * _{~adjectifs} _~riche ) $godname is the God of '_0 _1?
	CMouton
	a:(~oui) Now that's kind of superficial.
		$specialite = '_1
		$dieu_concept = 1
	a:(~non) Yeah, you don't want such a greedy god.

s: (!not ~dieu * of * _{~adjectifs} _~objects ) $godname is the God of '_0 _1?
	CMouton
	a:(~oui) Now that is quite concrete!
		$specialite = '_1
		$dieu_objet = 1
	a:(~non) Ok, that didn't make much sense anyways.

s: (!not ~dieu * of * _{~adjectifs} _~nounlist ) $godname is the God of '_0 _1?
	CMouton
	a:(~oui) That is quite particular.
		$specialite = '_1
		$dieu_concept = 1
	a:(~non) Yeah, you don't want such a specific god.

s: (<<~dieu change [rule specialty]>>) That sounds a bit shifty.
	CMoins
	$personnalite -= 1

#  ----------------------------------------------------------------
#  God family
#  ----------------------------------------------------------------

s: (<<~dieu ~family_members ~animals>>) Part god, part beast hmm? That's interesting.
	CMouton
	a:(~why) I just think that some animals act like they own the place.

s: (<<~dieu ~family_members ~appliances>>) Part god, part machine then? I don't know how I feel about that.
	CMouton
	a:(~why) Well, they're kind of everywhere now aren't they?

s: (!no !your << ~dieu [his her its their of] ~family_members >>) Oh, that clarifies the family tree.
	CMouton

s: (<< ~dieu [unique "only god"] >>) What? You mean it would be the ONLY God in the universe?
	CMouton
	a:(~oui) That's bold! The other Gods will be so angry!
	a:(~non) Ah! You got me there for a second. One God! Imagine what all the others would say!

s: (no other god) Ah! Wait till they hear you say that!
	CMouton

#  ----------------------------------------------------------------
#  God comparison
#  ----------------------------------------------------------------

?: (<<"Lahar" "lahar" [who what]>>) You don't know Lahar the mighty God of cattle?
	a:(~non) Well he's the mighty God of cattle.
	a:(~oui) Obviously.

?: ([what who] be your ~dieu) Well, my God is the great Lahar of course.

s: (<<~dieu [stronger strong mighty]>>) Could it lift that big rock over there?
	CMouton
	a:([~oui problem]) Ooh! That's strong!
		CPlus
		$personnalite += 1
		$identity += 1
		$powerfulgod = 1
	a:(~non) Then it is not so strong.
		CMoins
		$personnalite -= 1
		$powerfulgod = 0

s: (<<~dieu ~damage_verbs Lahar [can could would will]>>) That's easy to say.
	CMouton

s: (~dieu * could * easily) Oh yeah?! I'm sure Lahar could do that too... maybe.

s: (~dieu * know * [all everything]) That's what they say, but have you asked $godname a difficult question?
	CMouton
	a:(~oui) Good, you're a clever prophet.
		CPlus
		$personnalite += 1
	a:(~non) You should have.

s: (<<~favorite ~dieu>>) $godname seems interesting, but I'm not sure that I'm ready to say that. ^gambit(~)

s: (<< ~dieu be [love lover]>>) That's a big change from Lahar.
	CPlus
	$personnalite += 1

#  ----------------------------------------------------------------
#  Character traits
#  ----------------------------------------------------------------

s: (~dieu * [aim want wish hope] * [please help assist] ) I like that in a god!
	CMouton
	CPlus
	$personnalite += 1

s: (<< ~dieu be ~sympathique >>) Oh yeah? So $godname is a benevolent God then?
	CMouton
	a:(~oui) I'll remember that.
		CPlus
		$personnalite += 1
	a:(~non) How would you describe its personality then?
		b: (_~adjective) ^input(he be '_0) ^fail(sentence)

s: (!no !not << ~dieu be ~antipathique >>) Well, most of them are.
	CMouton
	CMoins
	$personnalite -= 1

s: (<< [no not] ~dieu be _~antipathique >>) Good, there are enough '_0 gods as it is.
	CPlus
	$personnalite += 1

s: (!not ![I me] ~dieu be [pretty quite very "a little"] _~adjective) So $godname is very '_0, uh?
	CMouton
	a:(~oui) Interesting.
	a:(~non) Then you should probably avoid that topic in your pitch.

s: (!not ![I me] ~dieu be _~adjective) So $godname is very '_0, uh?
	CMouton
	a:(~oui) Interesting.
	a:(~non) Then you should probably avoid that topic in your pitch.

s: (!not ![I me] ~dieu be _~NOUN) So $godname is a bit like '_0?
	CMouton
	a:(~oui) Interesting.
	a:(~non) Then you should probably avoid that topic in your pitch.

s: (!not ![I me] ~dieu be _~role_nationality_member) Wait, $godname is '_0 ?
	a:(~oui) That's ulmash.
	a:(~non) Oh, my bad.

s: (<<!not ~dieu ~like ~hobby>>) $godname is into that? I though that Gods were too busy for that type of stuff.

s:(!no !not ~dieu * be * [formless shapeless ethereal evanescent amorphous]) Then he wouldn't stand a proper fight with Lahar.
	CMoins
	$classe -= 1

s:(~dieu * not * [picky choosy]) I can see that.



#  ----------------------------------------------------------------
#  Actions
#  ----------------------------------------------------------------

s:(~dieu * [make create produce] * ~nounlist) I'll believe it when I see it.
	CMouton

#  ----------------------------------------------------------------
#  Appearances
#  ----------------------------------------------------------------

s: (<< ~dieu be _[old young] >>) How _0 exactly?
	CMouton
	a: ( * ) I didn't expect that. Is that even _0 in god terms?

s: (!you << ~dieu be ~good_appearance >>) A good part of religion is about good appearances, isn't it?
	CPlus
	$classe += 1

s: (!you  ~dieu *  be * _~bad_appearance ) Did you say '_0? I usually like a god that I can show off a bit.
	CMouton
	CMoins
	$classe -= 1

s: (!I !no !not ~dieu * [look resemble like]) That's not how I pictured $godname at first.
	CMouton

#  ----------------------------------------------------------------
#  Weather
#  ----------------------------------------------------------------

s:( << ~reallybadweather ~dieu >> ) That's some extreme weather. Does $godname has his say in that as well?
	$$bweather = ^pick(~reallybadweather)
	$$bweather = ^pos(CAPITALIZE $$bweather)
	$godname = ^join(AUTOSPACE $godname The $$bweather)
	a:(~oui) Scary stuff. I think I'll call your god $godname from now one.
		CMoins
		$personnalite -= 1
		$powerfulgod = 1
	b:(~non) A powerful god could make this pasture green, but then again it would be hard not to piss off whoever's upstair.

s:( << ~natural_disasters ~dieu >> ) That's bad. Does your god control all of that too?
	$$ndisaster = ^pick(~natural_disasters)
	$$ndisaster = ^pos(CAPITALIZE $$ndisaster)
	$godname = ^join(AUTOSPACE $godname The $$ndisaster)
	a:(~oui) Scary. It'll be $godname from now one.
		CMoins
		$personnalite -= 1
		$powerfulgod = 1
	b:(~non) That's ulmash I guess, since I would be in constant fear of sinning.