GPDID v1.0

/********************************************
 * GetPlayerDialogID(playerid) V1.0         *
 * Credits: wups                            *
 ********************************************/

// include
#include <a_samp>


// defines
#if defined _GPDID
    #endinput
#endif
#define _GPDID

// The main function:
#define GPDID GetPlayerDialogID
#define GetPlayerDialogID(%0) (GPD_pdialog[%0])

// variables
new
    GPD_pdialog[MAX_PLAYERS];

static
    bool:GPD_OPC,
    bool:GPD_ODR;


// forwards
// forward OnPlayerDialogChange(playerid,lastdialog,newdialog);
// I don't think this is needed.

// Functions

// ShowPlayerDialog
stock GPD_ShowPlayerDialog(playerid,dialogid,style,caption[],info[],button1[],button2[])
{
    GPD_pdialog[playerid]=dialogid;
    return ShowPlayerDialog(playerid,dialogid,style,caption,info,button1,button2);
}

#define ShowPlayerDialog GPD_ShowPlayerDialog

public OnPlayerConnect(playerid)
{
    GPD_pdialog[playerid]=-1;
    return (GPD_OPC)?CallLocalFunction("GPD_OnPlayerConnect","i",playerid):1;
}

#if defined _ALS_OnPlayerConnect
    #undef OnPlayerConnect
#else
    #define _ALS_OnPlayerConnect
#endif

#define OnPlayerConnect GPD_OnPlayerConnect
forward GPD_OnPlayerConnect(playerid);

// OnPlayerKeyStateChange
public OnDialogResponse(playerid,dialogid,response,listitem,inputtext[])
{
    GPD_pdialog[playerid]=-1;
    return (GPD_ODR)?CallLocalFunction("GPD_OnDialogResponse","iii",playerid,dialogid,response,listitem,inputtext):1;
}
#if defined _ALS_OnDialogResponse
    #undef OnDialogResponse
#else
    #define _ALS_OnDialogResponse
#endif
#define OnDialogResponse GPD_OnDialogResponse
forward GPD_OnDialogResponse(playerid,dialogid,response,listitem,inputtext[]);


#if !defined FILTERSCRIPT
    // OnGameModeInit
    public OnGameModeInit()
    {
        GPD_ODR = (funcidx("GPD_OnDialogResponse") != -1);
        GPD_OPC = (funcidx("GPD_OnPlayerConnect") != -1);
        return (funcidx("GPD_OnGameModeInit") != -1)?CallLocalFunction("GPD_OnGameModeInit",""):1;
    }
    #if defined _ALS_OnGameModeInit
        #undef OnGameModeInit
    #else
        #define _ALS_OnGameModeInit
    #endif
    #define OnGameModeInit GPD_OnGameModeInit
    forward GPD_OnGameModeInit();
#else
    // OnFilterScriptInit
    public OnFilterScriptInit()
    {
        GPD_ODR = (funcidx("GPD_OnDialogResponse") != -1);
        GPD_OPC = (funcidx("GPD_OnPlayerConnect") != -1);
        return (funcidx("GPD_OnFilterScriptInit") != -1)?CallLocalFunction("GPD_OnFilterScriptInit",""):1;
    }
    #if defined _ALS_OnFilterScriptInit
        #undef OnFilterScriptInit
    #else
        #define _ALS_OnFilterScriptInit
    #endif
    #define OnFilterScriptInit GPD_OnFilterScriptInit
    forward GPD_OnFilterScriptInit();
#endif


// The end.