<<<<<<<< .../fl-inlined/epilogues/setup.tra
@1 = ~After <CHARNAME> ascended, Sarevok became a pirate. Soon after he found and adopted a Miniature Giant Space Parrot, and all was well.~
@2 = ~After the evil Melissan was defeated, <CHARNAME> opted to remain mortal. Sarevok found this decision to be a real chin-scratcher.~
>>>>>>>>
LOAD_TRA ".../fl-inlined/epilogues/setup.tra"

<<<<<<<< .../fl-inlined/epilogues/old_ar6200.baf
IF
  Global("StartEndBios","AR6200",1)
  InParty("Sarevok")
  Global("SarevokBio","GLOBAL",0)
THEN
  RESPONSE #100
    SetGlobal("SarevokBio","GLOBAL",1)
    TextScreen("SAREVND")
    SmallWait(1)
    Continue()
END
>>>>>>>>
<<<<<<<< .../fl-inlined/epilogues/new_ar6200.baf
IF
  Global("StartEndBios","AR6200",1)
  InParty("Sarevok")
  Global("SarevokBio","GLOBAL",0)
  Global("PlayerChoseEssence","GLOBAL",1) // This is the variable for whether or not the player ascended; good/evil is determined elsewhere
THEN
  RESPONSE #100
    SetGlobal("SarevokBio","GLOBAL",1)
    TextScreen("fl#sarv1")
    SmallWait(1)
    Continue()
END

IF
  Global("StartEndBios","AR6200",1)
  InParty("Sarevok")
  Global("SarevokBio","GLOBAL",0)
  Global("PlayerChoseEssence","GLOBAL",0)
THEN
  RESPONSE #100
    SetGlobal("SarevokBio","GLOBAL",1)
    TextScreen("fl#sarv2")
    SmallWait(1)
    Continue()
END
>>>>>>>>

// Create one 2da for each epilogue; there are many ways of doing this
ACTION_FOR_EACH traref IN 1 2 BEGIN
  COPY_EXISTING sarevnd.2da "override/fl#sarv%traref%.2da" // The file name can be 8 characters at most, and must include a (your) modder prefix
    SET_2DA_ENTRY 1 2 3 RESOLVE_STR_REF ((AT traref))
END

// This is not necessarily a good way of patching AR6200.BCS, but it is expedient
COPY_EXISTING ar6200.bcs override
  REPLACE_BCS_BLOCK ".../fl-inlined/epilogues/old_ar6200.baf"
                    ".../fl-inlined/epilogues/new_ar6200.baf"
BUT_ONLY