lib32-gcr-3.6.2-2: PKGBUILD

# Maintainer: josephgbr <rafael.f.f1@gmail.com>

# Contributor: Ionut Biru <ibiru@archlinux.org>

# Contributor: jtts

 

_pkgbase=gcr

pkgname=lib32-${_pkgbase}

pkgver=3.6.2

pkgrel=2

pkgdesc="A library for bits of crypto UI and parsing (32-bit)"

arch=(x86_64)

url="http://www.gnome.org"

license=('GPL2')

depends=('lib32-dconf' 'desktop-file-utils' 'lib32-gtk3' 'lib32-libgcrypt' 'lib32-p11-kit' ${_pkgbase}'>='${pkgver}-${pkgrel}) # 'desktop-file-utils' 'hicolor-icon-theme'

makedepends=('intltool' 'gcc-multilib') # 'gobject-introspection'

options=(!libtool)

#install=gcr.install

source=(http://download.gnome.org/sources/$_pkgbase/${pkgver%.*}/$_pkgbase-$pkgver.tar.xz)

#        10-gcr.conf)

sha256sums=('f709db2435e3635b68d8aa212863e0a8e81b1cc33442852a5183762876c7be9b')

#            '5f2eda7175ae9f23ee0e09d2beceb24fd2f6daafd7bddfcc1c1f5a3734eb60fc')

 

build() {

  export CC='gcc -m32'

  export CXX='g++ -m32'

  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'

 

  cd "$_pkgbase-$pkgver"

  ./configure --prefix=/usr \

    --libdir=/usr/lib32 \

    --libexec=/usr/lib32/gcr \

    --disable-static \

    --disable-update-mime \

    --disable-schemas-compile \

    --enable-introspection=no

  make

}

 

package() {

  cd "$_pkgbase-$pkgver"

  make DESTDIR="$pkgdir" install

 

  # gcr wants to lock some memory to prevent swapping out private keys

  # https://bugs.archlinux.org/task/32616

  # https://bugzilla.gnome.org/show_bug.cgi?id=688161

  #install -Dm644 ../10-gcr.conf "$pkgdir/etc/security/limits.d/10-gcr.conf"

 

  # cleanup for lib32 package

  rm -rf "$pkgdir"/usr/{bin,include,share}

}

 

# vim:set ts=2 sw=2 et: