Untitled

/*
  City Building 062211
  2011-06-22 by Jedidiah Hurt
  For use with Structure Synth (structuresynth.sourceforge.net)
  This work is licensed under a Creative Commons Attribution-NonCommercial-ShareAlike 3.0 Unported License.
*/

set maxdepth 40000
set maxobjects 40000

set seed 78
set background #aaa

city
{ z -2.4 } city
{ z  -4.8 } city
{ z  -7.2 } city

rule city {
  8 * { x 2.4 b 0.95 sat 0 } neighborhood
}

rule neighborhood {
  { x -0.6 z -0.6 } block
  { x 0.6 z 0.6 } block
  { x -0.6 z 0.6 } block
  { x 0.6 z -0.6 } block
}

rule block {
  skyscraper
}

rule block md 3 > house {
  { s 0.5 y -0.5 } neighborhood
}

rule skyscraper {
  spirescraper
}

rule skyscraper {
  parallelscraper
}

rule parallelscraper md 5 {
  { y 0.4 } parallelscraper
  box
}

rule spirescraper md 5 > spire {
  { y 1 } spirescraper
  box
}

rule spirescraper md 3 > spire {
  { y 1 } spirescraper
  box
}

rule spirescraper md 8 > spire {
  { y 1 } spirescraper
  box
}

rule spire {
  { y -1 s 0.03 } parallelspire
}

rule spire {
  shrinkingspire
}

rule parallelspire md 20 {
  { y 1 } parallelspire
  box
}

rule parallelspire md 30 {
  { y 1 } parallelspire
  box
}

rule parallelspire md 40 {
  { y 1 } parallelspire
  box
}

rule shrinkingspire md 10 {
  { y 0.5 s 0.5 } shrinkingspire
  box
}

rule shrinkingspire md 10 {
  { y 0.75 s 0.75 } shrinkingspire
  box
}

rule shrinkingspire md 10 {
  { y 0.9 s 0.9 } shrinkingspire
  box
}

rule house {
  box
}