Untitled

#Contributor: serp <serp256 at gmail dot com>
srcname=lwt
pkgname="ocaml-$srcname"
pkgver=2.3.1
pkgrel=1
pkgdesc="A library for cooperative threads in OCaml"
arch=('i686' 'x86_64')
url="http://ocsigen.org/lwt/"
license=('LGPL')
depends=('ocaml>=3.12.0' 'ocaml-findlib' 'ocaml-react' 'ocaml-text' 'libev')
source=(http://ocsigen.org/download/$srcname-$pkgver.tar.gz)
md5sums=('fb7f3600a075c94a94eacf2464c09feb')
conflicts=('lwt')

build() {
        cd $srcdir/$srcname-$pkgver

        ./configure --enable-toplevel --enable-react --enable-text

        env DESTDIR="$pkgdir" \
        OCAMLFIND_DESTDIR="$pkgdir/$(ocamlfind printconf destdir)" \
        make
}


package() {
        mkdir -p "$pkgdir/$(ocamlfind printconf destdir)"
        mkdir -p "$pkgdir/$(ocamlfind printconf destdir)/stublibs"
        cd $srcdir/$srcname-$pkgver
        env DESTDIR="$pkgdir" \
        OCAMLFIND_DESTDIR="$pkgdir/$(ocamlfind printconf destdir)" \
        make install
        install -Dm 644 LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
}