spotify PKGBUILD with gtk2 2.24.24 binary

# Maintainer: Gadget3000 <gadget3000@msn.com>
# Contributor: Eothred <yngve.levinsen@gmail.com>

pkgname=spotify
pkgver=0.9.11.27
_anotherpkgver=.g2b1a638.81-1
pkgrel=1
pkgdesc="A proprietary peer-to-peer music streaming service"
arch=('x86_64' 'i686')
license=('custom:"Copyright (c) 2006-2013 Spotify Ltd"')
install=spotify.install
url="http://www.spotify.com"
changelog='spotify.changelog'
options=('!strip')
conflicts=('spotify-beta')

if [ "${CARCH}" = "x86_64" ]; then
    md5sums=('778a0150fc9c0205f06a620a60f1365c')
  _carch=_amd64
  pkgrel=1
elif [ "${CARCH}" = "i686" ]; then
  md5sums=('20113ac3d6760ded6940fef8143fa9a3')
  _carch=_i386
  pkgver=0.9.4.183
  _anotherpkgver=.g644e24e.428-1
fi

source=("http://repository.spotify.com/pool/non-free/s/${pkgname}/${pkgname}-client_${pkgver}${_anotherpkgver}${_carch}.deb"
'spotify'
'spotify.protocol')

md5sums+=('8d7059f889257fca61edb926bf419111'
'ef25ddc5b6bf8fe1a0d64cbd79e1f7b4')

if [ "${CARCH}" = "x86_64" ]; then
    source+=("http://seblu.net/a/arm/packages/g/gtk2/gtk2-2.24.24-1-x86_64.pkg.tar.xz")
    md5sums+=('fe9682217264ea780a7a56552f304a36')
fi

depends=("alsa-lib>=1.0.14" "glibc>=2.6" "libxss" "qtwebkit" "gconf" "nspr>=4.0"
         "nspr<5.0" "nss" "dbus" "systemd" "libgcrypt15" "gtk2")
optdepends=('desktop-file-utils: Adds URI support to compatible desktop environments'
            'ffmpeg-compat: Adds support for playback of local files')

package() {
  cd "${srcdir}"

  ar x "${pkgname}-client_${pkgver}${_anotherpkgver}${_carch}.deb" > /dev/null
  tar -xzf data.tar.gz -C "${pkgdir}"

  install -d "${pkgdir}/usr/share/"
  mv "${pkgdir}/opt/spotify" "${pkgdir}/usr/share/"
  rm -r "${pkgdir}/opt"

  install -d "${pkgdir}/usr/share/spotify/libs/"

  # Bin Script
  install -Dm755 "${srcdir}/spotify" "${pkgdir}/usr/bin/spotify"

    if [ "${CARCH}" = "x86_64" ]; then
        install -D "${srcdir}/usr/lib/libgdk-x11-2.0.so.0.2400.24" "${pkgdir}/usr/share/spotify/libs/libgdk-x11-2.0.so.0.2400.24"
        ln -s "${pkgdir}/usr/share/spotify/libs/libgdk-x11-2.0.so.0"{.2400.24,}

        install -D "${srcdir}/usr/lib/libgtk-x11-2.0.so.0.2400.24" "${pkgdir}/usr/share/spotify/libs/libgtk-x11-2.0.so.0.2400.24"
        ln -s "${pkgdir}/usr/share/spotify/libs/libgtk-x11-2.0.so.0"{.2400.24,}
  elif [ "${CARCH}" = "i686" ]; then
    # libplc4.so
    ln -s /usr/lib/libplc4.so "${pkgdir}/usr/share/spotify/libs/libplc4.so.0d"

    # libnspr4.so
    ln -s /usr/lib/libnspr4.so "${pkgdir}/usr/share/spotify/libs/libnspr4.so.0d"

    # libnss3.so
    ln -s /usr/lib/libnss3.so "${pkgdir}/usr/share/spotify/libs/libnss3.so.1d"

    # libnssutil3.so
    ln -s /usr/lib/libnssutil3.so "${pkgdir}/usr/share/spotify/libs/libnssutil3.so.1d"

    # libsmime3.so
    ln -s /usr/lib/libsmime3.so "${pkgdir}/usr/share/spotify/libs/libsmime3.so.1d"

    # openssl
    ln -s /usr/lib/libssl.so "${pkgdir}/usr/share/spotify/libs/libssl.so.0.9.8"
    ln -s /usr/lib/libcrypto.so "${pkgdir}/usr/share/spotify/libs/libcrypto.so.0.9.8"
  fi

  # libudev.so
  ln -s /usr/lib/libudev.so "${pkgdir}/usr/share/spotify/libs/libudev.so.0"

  # Copy license
  install -Dm644 "${pkgdir}/usr/share/doc/${pkgname}-client/copyright" "${pkgdir}/usr/share/licenses/${pkgname}/copyright"

  # Copy protocol file if KDE is installed
  if [ -f /usr/bin/startkde ]; then
    echo "Installing with KDE support"
    install -Dm644 "${srcdir}/spotify.protocol" "${pkgdir}/usr/share/kde4/services/spotify.protocol"
  fi
}