Combomod modified batch file for TFTDextender 1.03

@echo off
cls
title ComboMod

if not exist geoscape.exe goto failure
if "%PROCESSOR_ARCHITECTURE%" == "" goto dosbox

%1bb_tact\errcode.exe botch
if exist TFTDextender.exe (
  del TFTDExtender.ini
  copy Geo.ini TFTDExtender.ini
  start /w TFTDextender geoscape.exe "0"
) else (
  if exist xcloader.exe start /w xcloader geoscape.exe "0"
  if not exist xcloader.exe start /w geoscape.exe "0"
)
%1bb_tact\errcode.exe check

if errorlevel 2 goto begin
goto realend

:begin
%1bb_tact\combomod.exe
if exist TFTDextender.exe (
  del TFTDExtender.ini
  copy Tac.ini TFTDExtender.ini
  start /w TFTDextender tactical.exe "1"
) else (
  if exist xcloader.exe start /w xcloader tactical.exe "1"
  if not exist xcloader.exe start /w tactical.exe "1"
)

%1bb_tact\combomod.exe cleanup

%1bb_tact\errcode.exe botch
if exist TFTDextender.exe (
  del TFTDExtender.ini
  copy Geo.ini TFTDExtender.ini
  start /w TFTDextender geoscape.exe "1"
) else (
  if exist xcloader.exe start /w xcloader geoscape.exe "1"
  if not exist xcloader.exe start /w geoscape.exe "1"
)
%1bb_tact\errcode.exe check

if errorlevel 2 goto begin
goto realend

:dosbox

echo You're running DOS, or perhaps DOSBox.
echo.
echo Sorry, but ComboMod is only compatible with the CE
echo version of the game, which in turn is Windows-only.
echo.

pause

goto realend

:failure

echo Load failure!
echo.
echo This probably means one of the below is true:
echo.
echo * You're not running this from your game directory.
echo * You're trying to run the DOS (original) version of the game - **ComboMod is CE ONLY**.
echo * You're trying to run the CE (Windows) version of the game under DOSBox.
echo * You're trying to run the CE (Windows) version of the game but haven't
echo   created a split copy of your game executable yet.
echo.
echo In the last case, running "_EXE Split.bat" should sort that for you.
echo.

pause

:realend
del TFTDExtender.ini