' bomberman.bas - textbasierter Bomberman Klon in FreeBasic
#LANG "fb"

' Variablen und co.
dim Dateiname as string
dim DateiNr as integer
dim taste as string = ""

dim as integer zeilen = 0
dim as integer spalten = 0
dim zeichen as string = ""

dim i as integer = 0
dim b as integer = 0
dim a as integer = 0

dim as integer x = 0
dim as integer y = 0

const as string FREI = " "
const as string FIGUR = "o"
const as string WAND = "#"
const as string BOMBE = "*"

dim as integer start_x = 0
dim as integer start_y = 0
dim as integer tmp = 0

dim as integer alt_x = 0
dim as integer alt_y = 0

dim as integer max_bomben = 3
dim as integer bomben = 0

' Funktionen und SUBs
declare sub zeigeWelt(welt() as string, zeilen as integer, spalten as integer)
declare function canMove(welt() as String, x as integer, y as integer) as boolean
declare function bewegeSpieler(welt() as string, x as integer, y as integer, alt_x as integer, alt_y as integer) as boolean
declare sub spielende()
declare sub abwarten(wartezeit as double)

' Karte die geladen werden soll eingeben
Dateiname = "karte01.txt"

dim daten as string


' Welt laden
DateiNr = FreeFile
if open(Dateiname for binary as #DateiNr) = 0 then

    daten = space(lof(DateiNr)) ' Dateigröße ermitteln
                    ' und mit Leerzeichen füllen

    get #DateiNr, , daten ' aktuelles Zeichen in daten speichern

    close #DateiNr
else
    print !"\34!!!FEHLER!!! beim laden der Datei\34"
end if

' Weltgröße ermitteln
spalten = instr(daten, any !"\r\n")-1
zeilen = len(daten) \ (spalten + iif(daten[spalten] = asc("\r"), 2, 1))

' Karte laden und in Array speichern...
dim welt(0 TO zeilen-1, 0 TO spalten-1) as string

x = 0
y = 0
For i = 0 to len(daten)-1
    if daten[i] = 10 then
        y += 1
        x = 0
        continue for
    EndIf
    if daten[i] = 13 then continue for

    welt(y, x) = chr(daten[i])

    ' Aktuelle Spieler Position feststellen
    if welt(y, x) = figur then
        start_x = x
        start_y = y
    end if

    x += 1
Next


color 3, 0 ' Spiel in einen schönen blau darstellen :-)
cls
zeigeWelt(welt(), zeilen, spalten)

' Spieler auf aktuelle Position in der Welt setzen
y = start_y
x = start_x

' Cursor unsichtbar machen
locate , , 0

' Hauptschleife
do
    taste = INKEY

    ' Tastatur abfragen und Spieler bewegen
    select case taste
        case "w"
            if bewegeSpieler(welt(), x, y-1, x, y) then
                y = y - 1
            EndIf

            zeigeWelt(welt(), zeilen, spalten)

        case "s"
            if bewegeSpieler(welt(), x, y+1, x, y) then
                y = y + 1
            EndIf
            zeigeWelt(welt(), zeilen, spalten)

        case "a"
            if bewegeSpieler(welt(), x-1, y, x, y) then
                x = x - 1
            EndIf
            zeigeWelt(welt(), zeilen, spalten)

        case "d"
            if bewegeSpieler(welt(), x+1, y, x, y) then
                x = x + 1
            EndIf
            zeigeWelt(welt(), zeilen, spalten)

        case chr(32)
            ' Bombe legen mit der Leertaste
            '
            if (max_bomben > bomben) and (welt(y, x) <> BOMBE) then
                welt(y, x) = "O" ' Spieler legt die Bombe
                zeigeWelt(welt(), zeilen, spalten)

                welt(y, x) = BOMBE ' Bombe legen
                bomben = bomben + 1
            end if
    end select

    sleep 1
loop until taste = chr(27) ' Spiel beenden mit ESC

' Spielende
spielende()
end

' Soll einfach nur die Welt auf dem Bildschirm ausgeben
'
sub zeigeWelt(welt() as string, zeilen as integer, spalten as integer)
    dim as integer j, k

    ' Bildschirm Position zurücksetzen
    locate 1, 1
  for j = 0 to (zeilen - 1)
        for k = 0 to (spalten - 1)
            print welt(j, k);
    next
    print
  next
end sub


function canMove(welt() as String, x as integer, y as integer) as boolean
    if y < lbound(welt,1) or y > ubound(welt, 1) then return false
    if x < lbound(welt,2) or x > ubound(welt, 2) then return false
    if welt(y, x) = WAND then return false
    if welt(y, y) = BOMBE then return false
    return true
End Function



' Soll den Spieler bewegen und Eingaben überprüfen ob Sie gültig sind
' und abfragen ob man gegen ein Objekt läuft usw
'
function bewegeSpieler(welt() as string, x as integer, y as integer, alt_x as integer, alt_y as integer) as boolean

    if not canMove(welt(), x, y) then return false

    if (welt(y, x) = FREI) or (welt(y, x) = FIGUR) then
        welt(y, x) = figur ' Spieler platzieren

        ' alte Spieler Position löschen, wenn keine Bombe gelegt wurde
        if welt(alt_y, alt_x) <> BOMBE then welt(alt_y, alt_x) = FREI

        return true
    end if

    return false
end function

' Soll einfach einige Dinge erledigen nach dem das Spiel vorbei ist
'
sub spielende()
    cls
    print "Danke fürs spielen :-)"
end sub

' wartet eine übergebene Wartezeit in Sekunden ab...
'
sub abwarten(wartezeit as double)
    dim as double zeit = 0.0

    zeit = timer

    do
    loop until timer > zeit + wartezeit
end sub