winsxs compress

@echo off
sc config msiserver start= disabled
sc config TrustedInstaller start= disabled
sc stop msiserver
sc stop TrustedInstaller

setlocal enabledelayedexpansion

pushd %windir%\winsxs
for /r %%f in (*) do (

    set attr=%%~af
    set c=!attr:~5,1!

    if "!c!" == "-"  (
        if %%~zf gtr 4096 (
                set multi=
                for /f "skip=1" %%p in ('fsutil hardlink list %%f') do set multi=1
                if not defined multi (
                echo %%f
                    takeown /A /F "%%f"
                    icacls "%%f" /grant *S-1-5-32-544:(F^)
                    Compact /C /A /I "%%f" >> "%~dp0wsxscompact.log"
                    icacls "%%f" /setowner *S-1-5-80-956008885-3418522649-1831038044-1853292631-2271478464 /L /C
                icacls "%%f" /reset
                )
        )
            rem else echo == %%f too small
    )
        rem else echo == %%f already compressed
)
popd

sc config TrustedInstaller start= demand
sc config msiserver start= demand
pause