s3File v1.1a

/*
    @author:    s3rious
    @name:      s3File - Easy File reading & writing
    @ver:       1.1 alpha

                                                                    in 2012
*/

// Includes -----------------------
#include < A_SAMP >

// Macros -------------------------
#define MAX_FILENAME    32
#define MAX_VALUES      128
#define MAX_KEYS        64
#define MAX_LINES       64

// News ---------------------------
new
    s3_g_Value[ MAX_LINES ][ MAX_VALUES ],  // Store value for each line.
    s3_g_Key[ MAX_LINES ][ MAX_KEYS ],      // Store key for each line.
    s3_g_FileN[ MAX_FILENAME ],             // Store filename o handled file.
    File:s3_g_File,                         // Main variable for store file path.
    s3_g_Line
    ;

// Check if file exist
stock s3_Exist(file[])
{
    return fexist(file);
}

// Function for create a new file
stock s3_Create(file[])
{
    new
       File:FCreate = fopen(file, io_write)
    ;
    return fclose(FCreate);
}

/*
*   Important function for load file
*   This function must be called as firts of all
*   other function (no for s3_Create function)
*/
stock s3_Load(file[])
{
    new
        s3_l_String[ 168 ],
        line = -1,
        delim
    ;

    s3_g_File = fopen(file, io_read);
    format(s3_g_FileN, MAX_FILENAME, file);

    while(fread(s3_g_File, s3_l_String))
    {
        line++;
        EscCharacter(s3_l_String);
        delim = chrfind('=', s3_l_String);

        // Save key string
        strmid(s3_g_Key[ line ], s3_l_String, 0, delim);

        // Save Value string
        strmid(s3_g_Value[ line ], s3_l_String, delim+1, strlen(s3_l_String));

        // And increase lines value
        s3_g_Line++;

    }
    return fclose(s3_g_File);
}

// This remove file and erase global variable values
stock s3_Remove(file[])
{
    if (!fexist(file))  return false;
    else
    {
        fremove(file);
        EraseVars();
    }
    return 1;
}

// Used to read for boolean variables
stock bool:s3_ReadBool(key[])
{
    return bool:strval(s3_Read(key));
}

// Used to read for float type of variable
Float:s3_ReadFloat(key[])
{
    return floatstr(s3_Read(key));
}

// Used to read integer type of variable
s3_ReadInt(key[])
{
    return strval(s3_Read(key));
}

/*
*   This function is called from each function and
*   type of variable is converted to respective type of called function
*/
s3_Read(key[])
{
    new
        line = -1
    ;

    while((line < s3_g_Line) && (line < MAX_LINES))
    {
        line++;

        if (!strcmp(key, s3_g_Key[ line ], false))
        {
            return s3_g_Value[ line ];
        }
    }
    return s3_g_Value[ 0 ];
}

/*
*   This write function is used for each function, which write value.
*   Function is used for save string variable too.
*/
stock s3_Write(key[], value[])
{
    new
        bool:s3_l_Pos = false,
        line = -1
    ;

    while((line < s3_g_Line) && (line < MAX_LINES))
    {
        line++;

        if (!s3_g_Key[ line ][ 0 ]) continue;

        if (strcmp(key, s3_g_Key[ line ], false) == 0)
        {
            format(s3_g_Value[ line ], MAX_VALUES, value);
            s3_l_Pos = true;
            break;
        }
    }

    if (!s3_l_Pos)
    {
        s3_g_Line++;
        format(s3_g_Key[ line ], MAX_KEYS, key);
        format(s3_g_Value[ line ], MAX_VALUES, value);
    }
}

// Used for write boolean type of variable to file
stock s3_WriteBool(key[], value)
{
    new
        s3_l_String[ 128 ]
    ;

    format(s3_l_String, MAX_FILENAME, "%d", value);
    s3_Write(key, s3_l_String);
}

// Used for write integer type of variable to file
stock s3_WriteInt(key[], value)
{
    new
        s3_l_String[ 128 ]
    ;

    format(s3_l_String, MAX_FILENAME, "%d", value);
    s3_Write(key, s3_l_String);
}

// Used for write float type of variable to file
stock s3_WriteFloat(key[], Float:value)
{
    new
        s3_l_String[ 128 ]
    ;

    format(s3_l_String, MAX_FILENAME, "%2.f", value);
    s3_Write(key, s3_l_String);
}

// Saved all changes and close handle file.
stock s3_Close()
{
    new
        s3_l_String[ 128 ],
        line = -1
    ;

    s3_g_File = fopen(s3_g_FileN, io_write);

    while((line < s3_g_Line) && (line < MAX_LINES))
    {
        line++;

        if (!strlen(s3_g_Key[ line ]) || !strlen(s3_g_Value[ line ])) continue;
        format(s3_l_String, sizeof(s3_l_String), "%s=%s\r\n", s3_g_Key[ line ], s3_g_Value[ line ]);

        fwrite(s3_g_File, s3_l_String);
    }
    EraseVars();

    s3_g_Line = 0;
    fclose(s3_g_File);
}

stock EscCharacter(s3_l_StrEsc[])
{
    new
        len = strlen(s3_l_StrEsc)
    ;

    if(s3_l_StrEsc[ len-2 ] == '\r') s3_l_StrEsc[ len-2 ] = '\0';
    if(s3_l_StrEsc[ len-1 ] == '\n')        s3_l_StrEsc[ len-1 ] = '\0';
}

stock EraseVars()
{
    // Erasing variable values
    for(new i = 0; i < s3_g_Line; i++)
    {
        s3_g_Key[ i ][ 0 ] = 0;
        s3_g_Value[ i ][ 0 ] = 0;
    }
    return 1;
}

chrfind(n, str[], pos = 0)  // Function by Y_Less
{
    new len = strlen(str);
    while(pos < len)
    {
        if(str[ pos ] == n) return pos;pos++;
    }
    return -1;
}