autoexec.bat

@ECHO OFF
set EXPAND=YES
SET DIRCMD=/O:N
cls
set temp=c:\
set tmp=c:\
path=a:\

IF "%config%"=="NOCD" GOTO QUIT
LH MSCDEX.EXE /D:oemcd001 /L:D

echo.
IF "%config%"=="SETUP_98" goto 98SETUP
IF "%config%"=="SETUP_ME" goto MESETUP
IF "%config%"=="SETUP_LP" goto 98LITE
IF "%config%"=="CD" goto YESCDROM
IF "%config%"=="CDUSB" goto YESCDROM
GOTO QUIT

:98SETUP
set CDROM=FOO23
FINDCD.EXE
if "%CDROM%"=="FOO23" goto NOCDROM
path=a:\;%CDROM%\
%CDROM%
deltree /Y C:\WIN98
deltree /Y C:\WIN9X
del C:\ntldr
cls
echo.
echo.
echo   Installation Options:
echo.
echo --1. Install from CD-ROM (DEFAULT): Need Valid Serial
echo.
echo --2. Install from Hard-Drive: Random Serial Accepted
echo.
echo --3. Cancel
echo.
echo      [Press a number]
CHOICE /C:123 /T:3,45 /N --
IF ERRORLEVEL 3 goto CANCEL
IF ERRORLEVEL 2 goto 98HD
IF ERRORLEVEL 1 goto 98CD
goto QUIT
:CANCEL
cls
echo.
echo ...Canceled!
echo.
goto QUIT
:98HD
cls
echo.
echo.
echo   !!WARNING!!
echo.
echo   Drive "C:" must be present, and formatted.
echo.
echo   If you have not done so already:
echo --Quit this prompt. Type "RESTART", and press enter.
echo --Start with, or without, CD/USB support options.
echo --Use "FDISK" command to create a primary partition.
echo --Use "FORMAT" command followed by the drive letter.
echo.
echo   You can delete the "C:\Win98" folder when the
echo   install is complete to regain hard-drive space.
echo.
echo   Press "Y" to continue, or "N" to quit.
echo.
CHOICE /C:YN /T:N,30 /N --
IF ERRORLEVEL 2 goto QUIT
IF ERRORLEVEL 1 goto NEXT
goto QUIT
:NEXT
xcopy WIN98 C:\WIN98\ /S
copy EXTRA\98LITE\p.l C:\WIN98\pidgen.dll
C:
cd. >ntldr
cd WIN98
SETUP.EXE /D /IE /IW /NF /NM /NTLDR
del C:\ntldr
cls
goto QUIT
:98CD
cls
cd. >C:\ntldr
cd \
cd WIN98
SETUP.EXE /D /IE /IW /NF /NM /NTLDR
del C:\ntldr
cls
goto QUIT

:MESETUP
set CDROM=FOO23
FINDCD.EXE
if "%CDROM%"=="FOO23" goto NOCDROM
path=a:\;%CDROM%\
%CDROM%
deltree /Y C:\WIN9X
del /y C:\ntldr
cd. >C:\ntldr
cd \
cd WIN9X
cls
echo.
echo.
echo   Write this serial down before
echo   continuing.
echo.
echo   XXXXX-XXXXX-XXXXX-XXXXX-XXXXX
echo.
echo   [Press any key to start setup]
echo.
pause >nul
SETUP.EXE /D /IE /IW /NF /NM /NTLDR
del C:\ntldr
cls
goto QUIT

:98LITE
set CDROM=FOO23
FINDCD.EXE
if "%CDROM%"=="FOO23" goto NOCDROM
path=a:\;%CDROM%\
%CDROM%
cd EXTRA
cd 98LITE
cls
echo.
call INSTALL.BAT
goto QUIT

:YESCDROM
set CDROM=FOO23
FINDCD.EXE
if "%CDROM%"=="FOO23" goto NOCDROM
path=a:\;%CDROM%\
%CDROM%
echo.
echo.
echo   Check drive "A:" for tools. Type
echo   the program name followed by "/?".
echo.
echo   Example:
echo   FORMAT /?
echo.
echo   You are currently on CD-ROM drive...
echo.
goto QUIT

:NOCDROM
echo.
echo   The Windows 98 Setup files were not found.
echo.

:QUIT