PKGBUILD nss-ldapd

# Maintainer: Kaiting Chen <kaiting.chen@kiwilight.com>
# Contributor: Cheer Xiao <xiaqqaix.at.gmail.com>

pkgname='nss-ldapd'
_pkgname='nss-pam-ldapd'
pkgver='0.8.10'
pkgrel='1'
pkgdesc='LDAP module for NSS and PAM'
arch=('i686' 'x86_64')
url="http://arthurdejong.org/$_pkgname/"
license=('LGPL2.1')
depends=('krb5' 'pam' 'libldap' 'libsasl')

backup=('etc/nslcd.conf')

sha1sums=('4dd50c0537a13f454625e0325b8c863e5adb48a8'
         'ad912a52741bbe79f0d344fc1bdfb3055a4a47c8'
         '6b25f351be8d91e92e7846e601ab655545759a4b')
source=("$url$_pkgname-$pkgver.tar.gz"
        'nslcd.rc.d'
        'nslcd.service')
install=nss-ldapd.install

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --libdir=/usr/lib \
    --localstatedir=/var \
    --enable-sasl \
    --with-pam-seclib-dir=/usr/lib/security \
    --with-nslcd-pidfile=/var/run/nslcd.pid \
    --with-nslcd-socket=/var/run/nslcd.sock
  make
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  make DESTDIR="$pkgdir" install
  install -Dm755 $srcdir/nslcd.rc.d $pkgdir/etc/rc.d/nslcd
  install -Dm755 $srcdir/nslcd.service $pkgdir/usr/lib/systemd/system/nslcd.service
}