Torn.com User Info

;Torn.com user info by Ford_Lawnmower irc.geekshed.net #Script-Help
menu Channel,Status {
  .$iif($group(#TornInfo) == On,$style(1)) TornInfo Trigger
  ..$iif($group(#TornInfo) == On,$style(2)) On: .enable #TornInfo
  ..$iif($group(#TornInfo) == Off,$style(2)) Off: .disable #TornInfo
}
#TornInfo on
On $*:Text:/^(\+|-|!|@)TornInfo.*/Si:#: {
  var %action $regml(1)
  if (%action isin +-) && ($regex($nick($chan,$nick).pnick,/(!|~|&|@)/)) {
    if (%action == +) {
      if ($istok(%TornInfoChanList,$+($network,$chan),32)) { .msg $chan $nick $chan is already running the TornInfo script }
      else {
        .enable #TornInfo
        Set %TornInfoChanList $addtok(%TornInfoChanList,$+($network,$chan),32)
        .msg $chan $nick has activated the TornInfo script for $chan .
      }
    }
    else {
      if (!$istok(%TornInfoChanList,$+($network,$chan),32)) { .msg $chan $nick $chan is not running the TornInfo script }
      else {
        Set %TornInfoChanList $remtok(%TornInfoChanList,$+($network,$chan),1,32)
        .msg $chan $nick has deactivated the TornInfo script for $chan .
      }
    }
  }
  elseif (!$timer($+(TornInfo,$network,$nick))) && ($istok(%TornInfoChanList,$+($network,$chan),32)) {
    .timer $+ $+(TornInfo,$network,$nick) 1 6 noop
    var %method $iif(%action == !,.notice $nick,$iif($regex($nick($chan,$nick).pnick,/(!|~|&|@|%)/),.msg $chan,.notice $nick))
    GetTornInfo %method $2-
  }
}
#TornInfo end
alias TornInfo { GetTornInfo echo -a $1- }
alias -l GetTornInfo {
  $1-2 Searching........
  var %sockname $+(TornInfo,$network,$2,$ticks)
  sockopen %sockname www.torn.com 80
  sockmark %sockname $1-2 $+(/profiles.php?XID=,$3)
}
On *:sockopen:TornInfo*: {
  if (!$sockerr) {
    sockwrite -nt $sockname GET $gettok($sock($sockname).mark,3,32) HTTP/1.0
    sockwrite -n $sockname Host: www.torn.com
    sockwrite -n $sockname $crlf
  }
  else { echo -st Socket Error $nopath($script) | sockclose $sockname | return }
}
On *:sockread:TornInfo*: {
  if ($sockerr) { echo -st Socket Error $nopath($script) | sockclose $sockname | return }
  else {
    var %TornInfo | sockread %TornInfo
    if ($regex(%TornInfo,/(Name:)<\/font>\s<font color.*><b>([^<]*)\[/i)) $gettok($sock($sockname).mark,1-2,32) $regml(1) $regml(2)
    elseif ($regex(%TornInfo,/(Age:)<\/font>([^<]*)<br>/i)) $gettok($sock($sockname).mark,1-2,32) $regml(1) $regml(2)
    elseif ($regex(%TornInfo,/(Job:)<\/font>([^<]*)<br>.*(Last\saction:)<\/font>([^<]*)<br>/i)) {
      $gettok($sock($sockname).mark,1-2,32) $regml(1) $regml(2) $regml(3) $regml(4)
      sockclose $sockname
    }
    elseif ($regex(%TornInfo,/(Faction:)<\/font>([^<]*)<br>/i)) $gettok($sock($sockname).mark,1-2,32) $regml(1) $regml(2)
    elseif ($regex(%TornInfo,/(Level:)<\/font>([^<]*)<br><font color.*>(Rank:)<\/font>([^<]*)<br>/i)) $gettok($sock($sockname).mark,1-2,32) $regml(1) $regml(2) $regml(3) $regml(4)
    elseif ($regex(%TornInfo,/(Gender:)<\/font>([^<]*)<br>/i)) $gettok($sock($sockname).mark,1-2,32) $regml(1) $regml(2)
  }
}