mm

#######################
###GENERAL VARIABLES###
#######################

setvar sleepstate (fluid|murky|very murky|thick|very thick|dense|very dense|stagnant|frozen)
setvar focuses 0
setvar mdspell 0
setvar spell 0
setvar origami flower
setvar cambrinth armband
setvar song minuet
setvar humming 0
setvar juggles 0
setvar jugglers feathers
setvar garbage bin|bucket|receptacle
setvar forage.item rock
setvar predict.counter 0
setvar MD.spell 0
setvar CV 0
setvar PG 0
setvar AUS 0

#####################
###General Actions###
#####################
action put #play beep1.wav when ^(\S+) whispers,
action put #play beep1.wav when .* (says|asks).*Lawtun
action put #play beep1.wav when .* asks you,
action put #play beep1.wav;send drop my $1 when ^Odd. Where did that (\w+) come

action goto BIGSTUN when ^The world fades to black as a giant, grinning skull

action send 15 $lastcommand when ^You are too tired to climb

action goto CONNECT when connection lost|Socket Error|connection dropped|connection closed|ReceiveCallback Exception

action send sleep when eval $mindstate > 2
action send awake when ^Overall state of mind: clear
action send sleep when ^Overall state of mind: %sleepstate

action goto STOPSCRIPT when The world grows blurry and indistinct.

action send stand when eval $sitting = 1
action goto exitnow when eval $health < 50
action goto exitnow when eval $stunned = 1
action goto exitnow when eval $dead = 1

action send $lastcommand when ^Sorry, you may only
action send $lastcommand when \.\.\.wait (1|2|3|4|5|6|7|8|9) seconds\.
action send $lastcommand when \.\.\.wait 1 second\.
action send $lastcommand when \.\.\.wait 10 seconds\.

action setvar humming 0 when You finish humming
action setvar humming 0 when You stop playing
action setvar humming 1 when ^You fumble slightly as you begin to hum
action setvar humming 1 when You begin to hum
action setvar humming 1 when You are already performing

action goto exitnow;send #play beep1.wav when eval $health < 50
action goto exitnow;send #play beep1.wav when eval $stunned = 1
action goto exitnow;send #play beep1.wav when eval $dead = 1
action goto exitnow;send #play beep1.wav when eval $webbed = 1

action send 8 listen to $1 when ^(\S+) begins to lecture you

action setvar CV 1 when ^You feel more aware
action setvar CV 1 when ^You sense the Clear Vision spell upon you
action setvar CV 0 when ^You feel less aware
action setvar PG 1 when ^The world around you brightens
action setvar PG 1 when ^You sense the Piercing Gaze spell upon you
action setvar PG 0 when ^The world around you returns
action setvar RF 1 when ^The refractive field gathers
action setvar RF 1 when ^You feel confident your Refractive Field has fully oscillated
action setvar RF 1 when ^Though you have been revealed, the Refractive Field spell pattern proceeds
action setvar RF 0 when ^You reveal yourself\.
action setvar RF 0 when ^The refractive field surrounding you fades

action send Harn 1 when ^You sense a tiny

action setvar predict on when ^While the sighting wasn't quite
action setvar predict on when ^Although you don't gain a complete
action setvar predict on when ^Too many futures cloud your mind
action setvar predict on when ^Although you learn nothing new
action setvar predict on when ^You learned something useful
action setvar predict on when ^You have not pondered your last observation sufficiently.
action setvar predict off when ^You scoop the bones back up.
action setvar predict off when ^The Moon Sphere

#Aura Sight
action setvar AUS 1 when ^Your color vision blossoms with new depth
action setvar AUS 1 when ^You sense the Aura Sight spell upon you
action setvar AUS 1 when ^The auras around you remain unchanged
action setvar AUS 0 when ^Your color vision returns to normal

timer clear
timer start
################
### MAIN LOOP###
################

MainLoop:
pause .5
send exp 0
gosub teachcheck
#gosub langclimb
Gosub Magic.exp.check
Gosub Lore.exp.check
#gosub langclimb
Gosub Survival.exp.check
goto mainloop


Magic.exp.check:
if $bleeding = 1 then send tend my right arm
if %humming = 1 then send stop hum
If $Primary_Magic.LearningRate < 30 then gosub Arcana
If $Arcana.LearningRate < 30 then gosub Arcana
If $Power_Perceive.LearningRate < 30 then gosub power
return

Lore.exp.check:
gosub Magic.exp.check
if $bleeding = 1 then send tend my right arm
#if $Mechanical_Lore.LearningRate < 30 then gosub mech
if $Astrology.LearningRate < 30 then gosub Astrology
if $Appraisal.LearningRate < 30 then gosub Appraisal
if $First_Aid.LearningRate < 30 then gosub Schol
return

Survival.exp.check:
gosub Magic.exp.check
if $bleeding = 1 then send tend my right arm
if $Perception.LearningRate < 8 then gosub Foraging
If $Foraging.LearningRate < 30 then gosub Foraging
#if $Climbing.LearningRate < 30 then gosub langclimb
#if $Swimming.LearningRate < 30 then gosub swimming
Return



##################
###TEACHING SUB###
##################

teachcheck:
pause .5
send ass teach
matchre teachcheckdone ^You are teaching
matchre teachcheckdone You are in this class\!
matchre teachcheckdone ^No one seems to be
matchre listen.skill ^(\w+) is teaching a class on \w+ \w+ \(compared to what you already know\) (Targeted Magic|Evasion) which is still open
matchre teachcheck1 ^Roundtime:
matchwait

teachcheck1:
pause .5
send ass teach
matchre teachcheckdone ^You are teaching
matchre teachcheckdone You are in this class\!
matchre teachcheckdone ^No one seems to be
matchre listen.teaching ^(\w+) is teaching .* new students\.
matchre teachcheckdone ^Roundtime:
matchwait

listen.skill:
pause .5
send listen to $1 obs
match teachcheckdone You cannot teach
match teachcheckdone You are already listening
match teachcheck1 is full
match teachcheckdone You begin to listen
match teachcheckdone cannot take another
match teachcheckdone isn't teaching\.
matchre teachcheckdone ^You must ask (\w+) for an invitation
matchwait

listen.teaching:
pause .5
send listen to $1 observe
match teachcheckdone You are already listening
match teachcheckdone is full
match teachcheckdone You begin to listen
match teachcheckdone cannot take another
match teachcheckdone isn't teaching\.
matchre teachcheckdone ^You must ask (\w+) for an invitation
matchwait

teachcheckdone:
return

########################
#### CLIMBING SUB  ####
########################
langclimb:
pause .5
setvar langclimb 0
goto climb

climb:
math langclimb add 1
if %langclimb = 1 then send climb other tree
if %langclimb = 2 then send climb third tree
if %langclimb = 3 then send climb fourth tree
if %langclimb = 4 then send climb fifth tree
if %langclimb = 5 then goto climbdone
match climbdown [Langenfirth,
match climb Roundtime:
matchwait

climbdown:
pause .5
send climb trunk
goto climb

climbdone:
return

########################
###SCHOLARSHIP/FA SUB###
########################


schol:
pause 0.5
if contains ("($righthandnoun|$lefthandnoun)","compendium") then goto schol2
Else send get my leather compendium
schol2:
pause 0.5
gosub humming
send study my compendium
match schol3 You continue studying
match schol3 You continue to study
match schol3 You attempt to continue
match schol3 In a sudden moment of clarity
match schol3 With a sudden moment
match schol3 You begin studying
match schol3 You begin to study
match scholdone You attempt to study the chart,
match Scholdone Why do you need to study
matchwait

schol3:
pause 0.5
send exp survival
if $First_Aid.LearningRate < 30 Then goto schol.next
else goto scholdone

schol.next:
pause .5
math turns add 1
send turn my compendium
if %turns >= 7 then goto scholdone
else goto schol2

scholdone:
pause 0.5
setvar turns 0
send stow my compendium
return

##################
###SPELLCASTING###
##################

PG:
pause .5
if %PG = 1 then return
if %humming = 1 then send stop hum
if $spelltime > 0 then send release
send prep PG
match spell.cast You raise
match spell.release You have to strain
matchwait

CV:
pause .5
if %cV = 1 then return
if %humming = 1 then send stop hum
if $spelltime > 0 then send release
send prep CV
match spell.cast You raise
match spell.release You have to strain
matchwait

spell.cast:
waitfor You feel fully prepared
send cast
return

spell.release:
send release
return

fm:
pause
if "$roomname" = "Northeast Wilds, Grimsage Way" then return
if %humming = 1 then send stop hum
if $spelltime > 0 then send release
send prep fm 10
pause .5
send observe moons in sky
match fmk moon Katamba
match fmx moon Xibar
match fmy moon Yavash
match fmx presence of Xibar.
match fmy presence of Yavash.
match fmk presence of Katamba.
match fmx Xibar lurking
match fmy Yavash lurking
match fmk Katamba lurking
match fmrelease That's a bit hard to do
match fmrelease Roundtime:
matchwait

fmk:
pause 2
send cast katamba
return

fmx:
pause 2
send cast xibar
return

fmy:
pause 2
send cast yavash
return

fmrelease:
pause 1
send release
return


DG:
pause .5
send prep dg
send look
match DGX blue moonbeam
match DGY red moonbeam
matchre DGK (black|grey) shadows
match DG.Done Obvious paths:
match DG.Done Obvious exits:
match DG.Done Also here:
matchwait

DGX:
waitfor You feel fully
send cast Xibar
goto dg.done

DGY:
waitfor You feel fully
send cast Yavash
goto dg.done

DGK:
waitfor You feel fully
send cast Katamba
goto dg.done

DG.Done:
pause .5
send rel
return

###################
###FORAGING SUB###
###################


Foraging:
pause .5
gosub humming
send exp survival
if $Perception.LearningRate < 8 then goto Forage
else return

Forage:
pause .5
send collect %forage.item
match Forage.kick too cluttered
match Forage.kick You manage to collect
match Forage.done Roundtime:
match Forage.done Forage on a ship?
matchwait

Forage.kick:
pause .5
send kick pile
goto Foraging

Forage.done:
pause .5
send kick pile
return

###############
###ASTROLOGY###
###############

astrology:
pause .5
send exp sk astro
if $Astrology.LearningRate < 30 then goto astro
else goto astrodone

scrollz:
pause .5
if %scrolls >= 13 then goto scrollsdone
math scrolls add 1
send get scroll from %pouch1
send unroll my scroll
pause .5
send read my scroll
match xscroll Roundtime:
match scrollz That's awfully hard
match scrollsdone I could not find
match scrollsdone You'll need to be holding
matchwait

xscroll:
pause .5
send roll my scroll
send put my scroll in %pouch2
match scroll2 What were you wanting
match scrollz You put
matchwait

scrollsdone:
pause .5
setvar scrolls 1
send get scroll from %pouch2;put scroll in %pouch1
match scrollsreturn What were you
match scrollsdone You put
matchwait

scrollsreturn:
return

predict.event:
#if $hidden = 0 then gosub hide
send study sky
match predict.event1 You feel a lingering sense
match predict.event You look deeply
match predict.event You are unable to sense
match astrodone You should try that where
match loopwait You feel it is too soon
matchwait

loopwait:
pause 20
goto astro

predict.event1:
send predict event
return

astro:
if "%stance" = "shield" and "$righthandnoun" = "%ME.weapon" then send stow %ME.weapon
if %PG = 0 then gosub pg
setvar observing sun
gosub observe %observing
setvar observing spider
gosub observe %observing
return

observe:
if "%predict" = "on" then goto predict.chart
pause .5
send observe $1 in sky
match observe You are a bit too distracted
match astrodone That's a bit hard to do
match astrodone You are unable to make use
match observe Roundtime:
match observe Most of the
match observe All but the smallest bit
match observe nearly a third
match observe Two-thirds
match observe A rather large cloud
match observe A tiny bit
match observe Over half
match observe Fully half
match observe Waxing still
match observe Nearly half
match observe A cloud has obscured parts
match observenext Your knowledge of the heavens
match observenext Your search for
match observenext Clouds obscure
match observenext Your observations are hindered
matchre observenext ^The constellation of .* is too faint
matchwait

observenext:
return

predict.chart:
pause .5
send get my chart
wait
send unroll my chart
match predict.next You unroll
match predict.next But that isn't rolled
match predict.chart You're too distracted
match astrodone I could not find
matchwait

predict.next:
pause .5
send align heavy thrown
goto predict.study

predict.study:
pause .5
send study my chart
match predict.study You're too distracted
match predict.chart.1 You rummage through
match predict.chart.1 pull out a large sheaf
match astrodone I could not find
matchwait

predict.chart.1:
pause .5
if %observing = "sun" then send align lockpicking
if %observing = "spider" then send align arcana
goto predict.study.1

predict.study.1:
pause .5
send study my chart
match predict.study.1 You're too distracted
match astrodone You rummage through
match predict.anal pull out a large sheaf
match astrodone I could not find
matchwait

predict.anal:
send predict anal
goto astrodone

astrodone:
pause 0.5
setvar predict no
setvar success yes
pause .5
send roll my chart
wait
send stow my chart in my backpack
return


#############################
###PERCEPTION/JUGGLING SUB###
#############################

perception:
#send hunt
pause 0.5
if %cV = 0 then gosub CV
math juggles add 1
#if %juggles > 12 then goto percepdone
send get my %jugglers
send juggle my %jugglers
match perception But you're not holding
match percepdone referring to?
match Percepexp Roundtime:
match percepdone Your injuries
matchwait

percepexp:
pause 0.5
send exp survival
if $Perception.LearningRate < 30 then Goto Perception
else send stow my %jugglers
goto percepdone

percepdone:
pause .5
setvar juggles 0
send stow my %jugglers
return


################
###VOCALS SUB###
################


humming:
pause
send exp sk vocals
if $Vocals.LearningRate < 30 then goto humming2
else goto humdone

humming2:
pause
if %humming = 0 then send hum %song
return

humdone:
pause
return

#########################
###MECHANICAL LORE SUB###
#########################


mech:
pause 0.5
send tap my envelope
match origami You tap
match foragegrass You lightly tap
match foragegrass I could not find
matchwait

origami:
pause 0.5
if $hidden = 1 then put unhide
send pull my envelope
match studyprimer You get a
match newenv The envelope is empty.
match newenv You must be either wearing
matchwait

newenv:
pause 0.5
send hold my envelope
send poke my envelope
pause 3
send get my envelope
match newenv2 You get
match count What were
matchwait

newenv2:
send wear my envelope
pause 0.5
goto origami

studyprimer:
pause 0.5
send study my %origami instruction
match study2 You take on a studious look.
match foldx Roundtime
matchwait

study2:
pause 0.5
gosub humming
send study my %origami instruction in my primer
waitfor Roundtime:
pause 0.5
goto foldx

foldx:
pause 0.5
gosub humming
send fold my paper
match foldx but it doesn't come out quite
match foldx make another fold
match foldx a fold
match nextx the final fold
match foldxwait ...wait
matchwait

foldxwait:
pause 3
goto foldx

nextx:
pause 0.5
send exhale my %origami
send drop my %origami
pause 0.5
send exp lore 0
pause
if $Mechanical_Lore.LearningRate < 30 then goto mech
else return

MECHx:
send exp lore 0
match MechDone % mind lock
match MechDone % dazed
match MechDone % bewilder
match origami EXP HELP
matchwait


foragegrass:
pause .5
send forage grass
match mechdone Roundtime:
match mechdone cluttered
match braid You manage to find some grass.
match mechdone You need to have one hand free
matchwait

braid:
pause 1
send braid my grass
match remgloves Your efforts are hindered
match foragegrass You need to have more material
match braidexp Roundtime:
match mechdone you need
match mechdone nothing more than wasted effort.
matchwait

remgloves:
pause 1
if matchre ($roomobjs,%garbage) then send put my grass in $1
wait
put remove my gauntlets
wait
put stow gauntlets
wait
goto foragegrass

braidexp:
pause 1
put exp sk mech
pause
if $Mechanical_Lore.LearningRate < 30 then goto braid
else goto mechdone

mechdone:
pause .5
if contains ($roomobjs,%garbage) then send put my grass in $1; put my grass in $1
return
pause .5
send drop my grass
send drop my grass
return


###############
###MAGIC SUB###
###############
###############
#PRIMARY MAGIC#
###############

Magic:
pause 0.5
if %humming = 1 then send stop hum
if $Primary_Magic.LearningRate < 30 then goto prep
Else return
Prep:
  send prep SOD 30
  matchre Harness ^You raise your arms
  matchre Harness ^You mutter a
  matchre Magic.Done ^You have to strain
  matchre Prep \.\.\.wait
  matchwait
Harness:
  #waitfor You feel fully prepared
  pause 10
  goto cast
  #send harness 8
  matchre Cast ^Roundtime:
  matchre magic.Done ^You strain,
  matchre Harness \.\.\.wait
  matchwait
Cast:
  pause 1
  send cast
  matchre Magic ^You gesture\.
  matchre Cast \.\.\.wait
  matchwait
Magic.Done:
  send release
  return

RF.Spell:
pause .5
if %humming = 1 then send stop hum
send prep rf
pause .5
waitfor You feel fully
goto RF.Harness

RF.Harness:
pause .5
send harn 6
matchre RF.Cast ^Roundtime
matchre RF.Done ^You strain
matchwait

RF.Cast:
Pause .5
send cast
matchre RF.Check ^The whole world begins
matchre RF.Harness ^You aren't holding
match RF.Done backfires
matchwait

RF.check:
send exp magic
if $Primary_Magic.LearningRate < 30 then goto RF.Prep
else goto RF.Done

RF.Prep:
send prepare RF
goto RF.Recast

RF.Recast:
waitforre ^The refractive field gathers around you
send cast
matchre RF.Check ^The whole world begins
matchre RF.Harness ^You aren't holding
matchre RF.Check ^The Refractive Field pattern
matchre RF.Check ^You don't have a spell
match RF.Done backfires
match RF.Done fails completely
matchwait

RF.Done:
pause .5
send release
return


######################
###POWER PERCEPTION###
######################

power:
pause .5
if %power.counter = 0 then send perc
if %power.counter = 1 then send perc katamba
if %power.counter = 2 then send perc yavash
if %power.counter = 3 then send perc xibar
if %power.counter = 4 then send perc moon
if %power.counter = 5 then send perc per
if %power.counter = 6 then send perc manip
if %power.counter = 7 then send perc psy
if %power.counter = 8 then send perc trans
if %power.counter = 9 then send perc stellar
if %power.counter = 10 then send perc planet
if %power.counter = 11 then send perc watch
wait
math power.counter add 1
if %power.counter = 12 then setvar power.counter 0
if %power.counter = 0 then return
goto power


#####################
###MAGICAL DEVICES###
#####################
var focuses 0

Arcana:
pause .5
send exp magic 0
wait
if $Arcana.LearningRate < 30 then goto Arcana.start
else if $Primary_Magic.LearningRate < 30 then goto Arcana.start
else goto arcana.done

Arcana.start:
pause .5
#setvar MD.spell 0
if %AUS = 0 then gosub AUS
if %humming = 1 then send stop hum
if %MD.spell = 0 then send prep SOD 18
if %MD.spell = 1 then if !contains ("$roomobjs", "shadowling") then if $Time.isDay != 1 then send prep shadowling
else if %MD.spell = 1 then send prep SOD 18
if %MD.spell = 2 then send prep MAF 16
if %MD.spell = 3 then send prep PG 16
if %MD.spell = 4 then send prep CV 16
if %MD.spell = 5 then send prep shad 16
if %MD.spell = 6 then send prep shear 16
match Arcana.done You have to strain
match ring You raise
match Ring You trace
matchwait

AUS:
Pause .5
send prep aus 18
gosub ring
return


MOONS:
send observe moons in sky
match COL.KATAMBA moon Katamba
match COL.XIBAR moon Xibar
match COL.YAVASH moon Yavash
match COL.XIBAR presence of Xibar.
match COL.YAVASH presence of Yavash.
match COL.KATAMBA presence of Katamba.
match COL.XIBAR Xibar's presence
match COL.YAVASH Yavash's presence
match COL.KATAMBA Katamba's presence
match COL.XIBAR Xibar lurking
match COL.YAVASH Yavash lurking
match COL.KATAMBA Katamba lurking
match COL.DONE That's a bit hard to do
match COL.DONE Roundtime:
match MOONS You are a bit too distracted
matchwait

COL.KATAMBA:
setvar COL Katamba
return

COL.YAVASH:
setvar COL Yavash
return

COL.XIBAR:
setvar COL xibar
return

COL.DONE:
setvar COL off
return


Ring:
pause .5
math focuses add 1
#if %focuses > 1 and "$preparedspell" = "Seal of Deflection" then goto focus
if %focuses > 1 then goto focus
#send remove my %cambrinth
send charge my %cambrinth 18
match empty while holding something else
match ring You harness
match focus too clumsy
match freeup hand free
match Arcana.done You are in no condition
match Arcana.done You strain,
matchwait

focus:
pause .5
setvar focuses 0
send focus my %cambrinth
match empty while holding something else
match focus but fail.
match Ring too clumsy
match Arcana.cast readying it for your use.
match Arcana.cast is intact.
match Arcana.cast resists, only absorbing part
match Arcana.cast is already holding as much power
matchwait

empty:
pause .5
send wear %cambrinth
send stow left
pause .5
send stow right
goto Ring

Arcana.cast:
pause .5
math MD.spell add 1
#if $spelltime < 20 then waitforre ^You feel fully prepared
if "%COL" = "off" then goto COL.OFF
if %MD.spell > 1 then setvar MD.spell 0
send cast
match Arcana A globe of shimmering blue fire
match Arcana The shimmering globe of blue fire
match Arcana You sense forces gathering about
match Arcana Tendrils of blue-white light silently shimmer into view
match Arcana With a dull roar
match Arcana With a barely perceptible screech
match Arcana You notice the shadows
match Arcana There is a subtle change in the lighting
match Arcana You feel more aware
match Arcana Pale yellow sparks begin to flicker
match Arcana Pale yellow sparks
match Arcana You briefly feel less aware
match Arcana The world around you wavers
match Arcana The world around you brightens
match Arcana Your spell causes the globe of blue
match Arcana shifting plexus of glistening azure lines
match Arcana The air around you shimmers
match Arcana Bright golden light flares for a moment
match arcana.done The auras around you remain unchanged
match arcana.done Your color vision blossoms
match arcana.done You are unable to harness
match arcana.done backfires
match Arcana is on the wrong side of Elanthia
matchwait

COL.OFF:
send release
setvar MD.spell 0
goto Arcana

Arcana.done:
pause .5
setvar focuses 0
#send wear my %cambrinth
send release
return


############
###HIDING###
############

hide:
if $hidden = 1 then return
if %humming = 1 then send stop hum
send hide
match hide.done Roundtime:
match hide.done Eh?
matchwait

hide.done:
return


###############
###APPRAISAL###
###############


Appraisal:
If $Appraisal.LearningRate < 30 then goto Appraise.1
else goto appraise.done
appraise.1:
pause .5
send app my case
matchre Appraise.2 ^Roundtime:
  matchre Appraise.2 ^I could not
  matchre Appraise.1 \.\.\.wait
  matchwait
appraise.2:
pause .5
send app my bala
matchre Appraise.3 ^Roundtime:
  matchre Appraise.3 ^I could not
  matchre Appraise.2 \.\.\.wait
  matchwait
appraise.3:
pause .5
send app my gloves
matchre Appraise.4 ^Roundtime:
  matchre Appraise.4 ^I could not
  matchre Appraise.4 ^It's hard to appraise fa
  matchre Appraise.3 \.\.\.wait
  matchwait
appraise.4:
pause .5
send app my bundle
matchre Appraise.5 ^Roundtime:
  matchre Appraise.5 ^Appraise what?
  matchre Appraise.5 ^I could not
  matchre Appraise.4 \.\.\.wait
  matchwait
appraise.5:
pause .5
send app my shield
matchre Appraise.done ^Roundtime:
  matchre Appraise.done ^I could not
  matchre Appraise.5 \.\.\.wait
  matchwait
appraise.6:
pause .5
send app my gem pouch
matchre Appraise.done ^Roundtime:
  matchre Appraise.done ^I could not
  matchre Appraise.6 \.\.\.wait
  matchwait
Appraise.Done:
  pause 2
  send close my gem pouch
  waitforre ^You close your|^That is already closed\.|^What were you
  return


#######################
###CLIMBING/SWIMMING###
#######################

swimming:
pause .5
gosub move 99
gosub move 80
gosub move 56
pause .5
swim:
move w
wait
move s
wait
move e
wait
move n
wait
send climb embankment
wait
send dive hole
wait
if $Swimming.LearningRate < 30 then goto swim

swimdone:
pause .5
gosub move 102
gosub move 81
gosub move 103
return



exitnow:
EXIT.NOW:
send #beep
send #beep
#play beep1.wav
echo $timedate
send exit
send exit
exit

STOPSCRIPT:
send #play beep1.wav
send #play beep1.wav
echo
echo
echo
echo
echo
echo
echo
echo
echo
echo
echo
echo
echo PULLED UP INTO A CONSULTATION SUITE!!!!
echo
echo
echo
echo
echo
echo
echo
send #abortscript

CONNECT:
echo *** You have been disconnected. Attempting to reconnect ***
put #echo >Log Lime *** Attempting to reconnect ***
action goto CONNECTED when You look around, taking a moment to get your bearings.
goto connecting
exit

CONNECTING:
put #connect
pause 15
if $connected = 1 then goto Connected
goto CONNECTING

CONNECTED:
Echo *** You have been Reconnected ***
put #echo >Log *** Reconnected ***
action remove You look around, taking a moment to get your bearings.
gosub clear
pause 5
goto mainloop