PKGBUILD

# Maintainer:  Devin Cofer <ranguvar@archlinux.us>
# Contributor: Hans-Kristian Arntzen <maister@archlinux.us>

pkgname=dolphin-emu-svn
pkgver=5218
pkgrel=1
pkgdesc="A GameCube and Wii emulator (Dev tree)"
arch=('i686' 'x86_64')
url="http://www.dolphin-emu.com/"
license=('GPL2')

makedepends=('subversion' 'scons>=0.98')
depends=('sdl' 'libxxf86vm' 'libao' 'wxgtk>=2.8' 'wxgtk<2.9' 'wiiuse' 'nvidia-cg-toolkit' 'glew')
provides=('dolphin-emu')
conflicts=('dolphin-emu' 'dolphin-emu-svn-bin')

source=('dolphin-emu.desktop'
        '32bitfix.patch'
        '64bitfix_RegisterView.cpp_undefinded_reference_to.patch')
sha256sums=('aba9fe897273743df70637336e86d911941734dd7c5f9aca0d53d3466b639b2f'
            'f0da1866d19f1744972614aaed44ac8335db33b6c0cdb715d3caad40a6de6f59'
            '205880c3b8ab30b15973ccd3c818c84a131b9ea9976d17c169c29459fd38bb11')
install=$pkgname.install

_svntrunk="http://dolphin-emu.googlecode.com/svn/trunk"
_svnmod="dolphin-emu-read-only"


build() {
        cd "$srcdir"
        msg "Performing source checkout..."
        if [ -d "$_svnmod/.svn" ]; then
                svn up --config-dir ./ -r $pkgver "$_svnmod" || return 1
        else
                svn co "$_svntrunk" --config-dir ./ -r $pkgver "$_svnmod" || return 1
        fi
        msg "Source checkout finished."
        rm -rf "$_svnmod-build"
        cp -r "$_svnmod" "$_svnmod-build" || return 1
        cd "$_svnmod-build"

        if [ "$CARCH" == "i686" ]; then  # Fix 32-bit build
                patch -i "$srcdir/32bitfix.patch" || return 1
        fi
        if [ "$CARCH" == "x86_64" ]; then  # Fix 64-bit wx* undefined reference to error
                cd "Source/Core/DolphinWX/Src/"
                patch -i "$srcdir/64bitfix_RegisterView.cpp_undefinded_reference_to.patch" || return 1
                cd "$srcdir/$_svnmod-build"
        fi

        scons || return 1
}
package() {
        cd "$srcdir/$_svnmod-build"

        mkdir -p "$pkgdir/opt/dolphin-emu"
        cp -r "Binary/Linux-$CARCH/"* "$pkgdir/opt/dolphin-emu/"

        # Remove SVN leftovers
        for svndir in $(find "$pkgdir" -name '.svn' -type d); do rm -r $svndir; done || return 1

        mkdir -p "$pkgdir/usr/bin"
        echo -e "#! /bin/sh\ncd /opt/dolphin-emu ; ./dolphin-emu" > "$pkgdir/usr/bin/dolphin-emu"
        chmod +x "$pkgdir/usr/bin/dolphin-emu"
        ln -s "$pkgdir/opt/dolphin-emu/dsptool" "$pkgdir/usr/bin/dsptool" || return 1
        install -Dm644 "$srcdir/dolphin-emu.desktop" "$pkgdir/usr/share/applications/dolphin-emu.desktop" || return 1
}