##maintainer Meow < meow at linux dot cn >
##edited by Yuanjie < huang at yuanjie dot name >

pkgname=mendeleydesktop
pkgver=1.3.1
pkgrel=1
pkgdesc="Academic software for managing and sharing research papers (desktop client)"
url=http://www.mendeley.com/release-notes/
arch=(i686 x86_64)
depends=(python2 qt libpng12)
license=(custom:mendeley_eula)
install=mendeleydesktop.install

_arch=$CARCH

[[ $CARCH = i686 ]] && _arch=i486

source=("http://download.mendeley.com/linux/$pkgname-$pkgver-linux-$_arch.tar.bz2"
        'mendeleydesktop.install')
md5sums=('9a733e695c49c348759a8493a07d8910'
         '16358cd53dc258a72efcaeab5a415217')

[[ $CARCH = x86_64 ]] &&  md5sums[0]='18715f40a084d99ff35141488aa0fd45'

package() {
    cd "$pkgname-$pkgver-linux-$_arch"

    rm -f share/doc/mendeleydesktop/*.txt

    install -dm755 "$pkgdir/opt/$pkgname/"
    mv bin lib share "$pkgdir/opt/$pkgname/"
    #ln -s "../lib/mendeleydesktop/libexec/mendeleydesktop.$_arch" "$pkgdir/opt/$pkgname/bin/$pkgname"
    cd "$pkgdir"
    sed -i '1s@^#!/usr/bin/python$@&2@' opt/"$pkgname"/bin/mendeleydesktop
    #install -Dm755 "bin/mendeleydesktop" "$pkgdir/usr/bin/mendeleydesktop"
    install -dm755 "$pkgdir"/usr/bin
    ln -s /opt/"$pkgname"/bin/mendeleydesktop "$pkgdir/usr/bin/mendeleydesktop"

    cd "$srcdir/$pkgname-$pkgver-linux-$_arch"
    install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

    install -dm755 "$pkgdir"/usr/share/applications
    ln -s /opt/"$pkgname"/share/applications/mendeleydesktop.desktop "$pkgdir"/usr/share/applications/

    #force mendeley to use bundled qt because which under qt 4.8 crashes at start point
    sed -i '0,/^use_system_qt = None$/s/use_system_qt = None/use_system_qt = True/1' "$pkgdir"/opt/"$pkgname"/bin/mendeleydesktop

    for size in 16 22 32 48 64 128;do
        install -dm755 "$pkgdir"/usr/share/icons/hicolor/${size}x${size}/apps
        ln -s /opt/"$pkgname"/share/icons/hicolor/${size}x${size}/apps/"${pkgname}".png \
          "$pkgdir"/usr/share/icons/hicolor/${size}x${size}/apps
    done
}