Final Fantasy XIV: Quick Blacklist

#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.3.8.1
 Author:         axpen

 Script Function:
    Quickly add last shout or tell to blacklist.
    Key combos are as follows;
    Add last shout: Control+Alt+Shift+DELETE
    Add last tell: Control+Alt+Shift+INSERT
    Terminate: Control+Alt+Shift+END

    MAKE SURE you are at your base UI, meaning no windows up or cursors up
    anywhere using numpad previously.
    Obviously key shortcuts can be changed, just use the AutoIt reference for
    "send".

    And as always I take no responsibility for account deletion for hacking if
    Square Enix deems this software "automation".

#ce ----------------------------------------------------------------------------

#include <Misc.au3>

; ------------------USER CONFIGURABLE OPTIONS------------------
; -----Hotkeys-----
HotKeySet("+^!{INSERT}", "BlistTell")
HotKeySet("+^!{DEL}", "BlistShout")
HotKeySet("+^!{END}", "Term")
; -----Delays-----
; Users of slower computers may need to increase this number it sets the delay
; (in milliseconds) in between key presses.
AutoItSetOption("SendKeyDelay", "200")
; Number of milliseconds to wait before sending confirmation button presses.
; Again slower computers may really want to up this number.
Global $confirmDelay = 500

Global $running = 1
Main()

Func Main()
    While $running = 1
        Sleep(100)
    WEnd
EndFunc

Func BlistShout()
    If WinActive("FINAL FANTASY XIV") Then
        _SendEx('{NUMPAD1}{NUMPAD8}{NUMPAD0}{NUMPAD0}{BS}"{HOME}{DEL}{DEL}{DEL}{DEL}{DEL}{DEL}')
        _SendEx('/blist add "{ENTER}')
        Sleep($confirmDelay)
        _SendEx('{NUMPAD0}')
    EndIf
EndFunc

Func BlistTell()
    If WinActive("FINAL FANTASY XIV") Then
        _SendEx('/blist add <r>{ENTER}')
        Sleep($confirmDelay)
        _SendEx('{NUMPAD0}{NUMPAD0}')
    EndIf
EndFunc

Func _SendEx($ss)
    While _IsPressed("10") Or _IsPressed("11") Or _IsPressed("12")
        Sleep(50)
    WEnd
    Send($ss)
EndFunc

Func Term()
    $running = 0
EndFunc