Everlasting Tools (MineTweaker3)

import minetweaker.data.IData;
import minetweaker.item.IItemStack;

var tag = { Unbreakable: true, Lore: [ "Everlasting" ] } as IData;
// Not sure how to make it work for any ItemTool, etc. so have a whitelist instead. :P
var tools =
[
	<minecraft:leather_helmet>,
	<minecraft:chainmail_helmet>,
	<minecraft:iron_helmet>,
	<minecraft:diamond_helmet>,
	<minecraft:golden_helmet>,
	<minecraft:leather_chestplate>,
	<minecraft:chainmail_chestplate>,
	<minecraft:iron_chestplate>,
	<minecraft:diamond_chestplate>,
	<minecraft:golden_chestplate>,
	<minecraft:leather_leggings>,
	<minecraft:chainmail_leggings>,
	<minecraft:iron_leggings>,
	<minecraft:diamond_leggings>,
	<minecraft:golden_leggings>,
	<minecraft:leather_boots>,
	<minecraft:chainmail_boots>,
	<minecraft:iron_boots>,
	<minecraft:diamond_boots>,
	<minecraft:golden_boots>,
	<minecraft:flint_and_steel>,
	<minecraft:fishing_rod>,
	<minecraft:carrot_on_a_stick>,
	<minecraft:shears>,
	<minecraft:bow>,
	<minecraft:wooden_hoe>,
	<minecraft:stone_hoe>,
	<minecraft:iron_hoe>,
	<minecraft:diamond_hoe>,
	<minecraft:golden_hoe>,
	<minecraft:wooden_sword>,
	<minecraft:stone_sword>,
	<minecraft:iron_sword>,
	<minecraft:diamond_sword>,
	<minecraft:golden_sword>,
	<minecraft:wooden_axe>,
	<minecraft:stone_axe>,
	<minecraft:iron_axe>,
	<minecraft:diamond_axe>,
	<minecraft:golden_axe>,
	<minecraft:wooden_pickaxe>,
	<minecraft:stone_pickaxe>,
	<minecraft:iron_pickaxe>,
	<minecraft:diamond_pickaxe>,
	<minecraft:golden_pickaxe>,
	<minecraft:wooden_shovel>,
	<minecraft:stone_shovel>,
	<minecraft:iron_shovel>,
	<minecraft:diamond_shovel>,
	<minecraft:golden_shovel>,
] as IItemStack[];

for i, tool in tools
{
	recipes.addShapeless( tool,
	                      [
	                      	tool.anyDamage().marked("tool"),
	                      	<minecraft:magma_cream>,
	                      	<minecraft:fire_charge>,
	                      	<minecraft:ender_eye>,
	                      	<minecraft:gold_block>,
	                      	<minecraft:diamond_block>,
	                      	<minecraft:emerald_block>,
	                      	<minecraft:iron_block>,
	                      	<minecraft:redstone_lamp>
	                      ],
	                      function( output, inputs, crafting )
	                      {
	                      	return inputs.tool.updateTag( tag );
	                      } );
}