Arch PKGBUILD for easytag-git (20120613)

# Maintainer:  Bernd Helm <AUR user raw>
# Contributor: Giancarlo Bianchi <AUR user hermes14>

pkgname=easytag-git
pkgver=20120613
pkgrel=1
pkgdesc="Utility for viewing, editing and writing ID3 tags of your MP3 files - git version with patches"
arch=('i686' 'x86_64')
license=('GPL')
url="https://github.com/stsquad/easytag"
depends=('id3lib' 'libid3tag' 'gtk2' 'libvorbis' 'flac' 'libmp4v2' 'speex' 'wavpack' 'desktop-file-utils')
makedepends=('git')
conflicts=('easytag')
install=easytag.install

_gitroot="git://easytag.git.sourceforge.net/gitroot/easytag/easytag"
_gitname="easytag"


build() {

  cd ${srcdir}
  msg "Connecting to GIT server...."

  if [ -d "${srcdir}/${_gitname}" ] ; then
    ( cd ${_gitname} && git pull --rebase )
  else
    git clone ${_gitroot}
  fi

  rm -rf ${_gitname}-build
  git clone ${_gitname} ${_gitname}-build
  cd ${_gitname}-build

  msg "GIT checkout done or server timeout"

  msg "Starting make..."

  ./autogen.sh
  ./configure --prefix=/usr
  make
}

package() {
  cd ${srcdir}/${_gitname}-build
  make DESTDIR=${pkgdir} install

  # Remove directory mimetype
  sed '/^MimeType=/ s@inode/directory;@@' \
    -i ${pkgdir}/usr/share/applications/easytag.desktop
}