xf86-video-openchrome-git PKGBUILD

# Maintainer: Marcel Dijkstra - <marcel~dykstra@gmail~com>
# Contributor: Pascal 'hardfalcon' Ernster <aur@hardfalcon.net>
_pkgname=xf86-video-openchrome
pkgname=$_pkgname-git
pkgver=release_0_3_3
pkgrel=1
pkgdesc="OpenChrome X driver for VIA UniChrome graphics cards."
arch=('i686' 'x86_64')
url="http://www.openchrome.org"
license=('GPL2')
depends=('intltool' 'xf86driproto' 'glproto' 'mesa' 'libxvmc')
makedepends=('git' 'pkgconfig' 'intltool' 'libtool' 'automake>=1.7.0' 'xorg-server-devel')
provides=('xf86-video-openchrome')
conflicts=('xf86-video-openchrome')
source=("git://anongit.freedesktop.org/openchrome/$_pkgname.git")
md5sums=('SKIP')

pkgver() {
    cd $_pkgname
    git describe --always | tr - .
}

build() {
    cd $_pkgname
    msg2 "Starting autogen.sh..."
    sh ./autogen.sh --prefix=/usr --enable-viaregtool
    msg2 "Starting make..."
    make
}

package() {
    cd $_pkgname
    msg2 "Starting make install..."
    make DESTDIR="$pkgdir" install
}