Numpad Menu

function SetMainMenuEntry(%num,%short,%function) //Short is what is displayed, function is what is called
{
	if($NPMM[%num] !$= "")
	{
		if(isObject(localclientconnection))
			messageBoxOK("Warning","Numpad Menu conflict. Multiple entries for " @ %num @ " were added.");
		else
			error("Numpad Menu conflict. Multiple entries for " @ %num @ " were added.");
	}
	$NPMM[%num] = %short;
	$NPMML[%num] = %function;
}

//All ShiftBrick are also SuperShiftBrick (except 1 and 3)
//All SuperShiftBrick values are -1, 0, or 1, instead of -3 or 3.
//0	CancelBrick
//1	ShiftBrick	0	0	-1
//2	ShiftBrick	-1	0	0
//3	ShiftBrick	0	0	1
//4	ShiftBrick	0	1	0
//5	ShiftBrick	0	0	-3
//6	ShiftBrick	0	-1	0
//7	RotateBrick	-1
//8	ShiftBrick	1	0	0
//9	RotateBrick	1
//+	ShiftBrick	0	0	3
//e	PlantBrick

package NumPadMenu
{
	function serverCmdCancelBrick(%client) //0
	{
		if(!isObject(%client.player.tempBrick))
			%client.Menu(0);
		else
			Parent::serverCmdCancelBrick(%client);
	}
	function serverCmdShiftBrick(%client,%x,%y,%z) //1,2,3,4,5,6,8,+
	{
		if(!isObject(%client.player.tempBrick))
		{
			if(%z == -1)
				%client.Menu(1);
			else if(%x == -1)
				%client.Menu(2);
			else if(%z == 1)
				%client.Menu(3);
			else if(%y == 1)
				%client.Menu(4);
			else if(%z == -3)
				%client.Menu(5);
			else if(%y == -1)
				%client.Menu(6);
			else if(%x == 1)
				%client.Menu(8);
			else if(%z == 3)
				%client.Menu("Plus");
		}
		else
			Parent::serverCmdShiftBrick(%client,%x,%y,%z);
	}
	function serverCmdRotateBrick(%client,%dir)
	{
		if(!isObject(%client.player.tempBrick))
		{
			if(%dir == 1)
				%client.Menu(9);
			else
				%client.Menu(7);
		}
		else
			Parent::serverCmdRotateBrick(%client,%dir);
	}
	function serverCmdPlantBrick(%client)
	{
		if(!isObject(%client.player.tempBrick))
			%client.Menu("Enter");
		else
			Parent::serverCmdPlantBrick(%client);
	}
	function serverCmdSuperShiftBrick(%client,%x,%y,%z) //2,4,5,6,8,+
	{
		if(!isObject(%client.player.tempBrick))
		{
			if(%x == -1)
				%client.Menu(2);
			else if(%y == 1)
				%client.Menu(4);
			else if(%z == -1)
				%client.Menu(5);
			else if(%y == -1)
				%client.Menu(6);
			else if(%x == 1)
				%client.Menu(8);
			else if(%z == 1)
				%client.Menu("Plus");
		}
		else
			Parent::serverCmdSuperShiftBrick(%client,%x,%y,%z);
	}
};
ActivatePackage(NumPadMenu);

function GameConnection::menu(%t,%m)
{
	if(%t.menuPageName !$= "")
		call(%t.menuPageName @ "_MenuPress",%t,%m);
	else
	{
		if(%m $= "Enter")
		{
			%t.menuPageName = "main";
			%menu = "\c3[0] \c6Close";
			for(%x=1;%x<10;%x++)
				if($NPMM[%x] !$= "")
					%menu = %menu SPC "\c3[" @ %x @ "] \c6" @ $NPMM[%x];
			%t.bottomPrint(%menu,0);
		}
	}
}

function main_MenuPress(%cl,%bt)
{
	if(%bt == 0)
	{
		%cl.menuPageName = "";
		%cl.bottomPrint("",1);
	}
	else if(%bt > 0 && %bt < 10)
		call($NPMML[%bt] @ "_ShowMenu",%cl);
}