PKGBUILD

# Contributor: riverscn<riverscn at gmail.com>
# Contributor: rainy<rainylau at gmail.com>
# Contributor: Lee.MaRS<leemars at gmail.com>
pkgname=ibus-pinyin-git
pkgver=20091010
pkgrel=1
pkgdesc="The PinYin Engine for IBus Input Framework"
arch=('i686' 'x86_64')
license=('LGPL')
url="http://ibus.googlecode.com"
depends=('ibus=1.2.0')
makedepends=('git' 'cvs' 'gnome-common')
provides=('ibus-pinyin=1.2.0')
conflicts=('ibus-pinyin')
install=ibus-pinyin.install
source=(http://ibus.googlecode.com/files/pinyin-database-1.2.99.tar.bz2)
noextract=(pinyin-database-1.2.99.tar.bz2)
md5sums=('d0951b8daa7f56a2cbd3b6b4e42532e0')

_gitname="ibus-pinyin"
_gitroot="git://github.com/phuang/ibus-pinyin.git"

build() {
    cd ${srcdir}

    msg "Connecting to ${_gitname} GIT server..."
    if [ -d ${_gitname} ]; then
        cd ${_gitname} && git pull origin master
        msg "The local files are updated."
    else
        git clone ${_gitroot}
    fi

    msg "GIT checkout done or server timeout. Preparing sources..."
    rm -rf "${srcdir}/${_gitname}-build"
    cp -r "${srcdir}/${_gitname}" "${srcdir}/${_gitname}-build"
    ln -s "${srcdir}/pinyin-database-1.2.99.tar.bz2" "${srcdir}/${_gitname}-build/data/db/open-phrase"

    msg "Starting make..."
    cd "${srcdir}/${_gitname}-build"
    ./autogen.sh --break-configure
    ./configure --prefix=/usr --libexecdir=/usr/lib/ibus --enable-db-open-phrase || return 1
    make || return 1
    make NO_INDEX=true DESTDIR=${pkgdir} install || return 1
}