#!/usr/bin/perl

use warnings;
use strict;

use Fcntl ":seek";

my $riffHeaderLength = length("RIFF") + 4;
my $ww2ogg = "ww2ogg";

{
    my @bnkFilenames = @ARGV;
    exit unless @bnkFilenames;

    BNK_FILE_LOOP:
    foreach my $bnkFilename (<@bnkFilenames>)
    {
        open(BNK_FILE, $bnkFilename) or die "Could not open BNK file '${bnkFilename}'";
        binmode BNK_FILE;

        my $input;

        read(BNK_FILE, $input, 8);
        my ($bkhd, $bkhdLength) = unpack("(A4L)<", $input);
        print "bkhd: $bkhd\n";
        print "bkhdLength: $bkhdLength\n";
        next BNK_FILE_LOOP unless $bkhd eq "BKHD";

        seek BNK_FILE, $bkhdLength, SEEK_CUR;

        read(BNK_FILE, $input, 8);
        my ($didx, $didxLength) = unpack("(A4L)<", $input);
        print "didx: $didx\n";
        print "didxLength: $didxLength\n";
        next BNK_FILE_LOOP unless $didx eq "DIDX";

        seek BNK_FILE, $didxLength, SEEK_CUR;

        read(BNK_FILE, $input, 8);
        my ($data, $dataLength) = unpack("(A4L)<", $input);
        print "data: $data\n";
        print "dataLength: $dataLength\n";
        next BNK_FILE_LOOP unless $data eq "DATA";

        my $dataContents;
        read(BNK_FILE, $dataContents, $dataLength);
        close(BNK_FILE);

        print "dataContents length: ". length($dataContents) ."\n";

        my $dataOffset = 0;
        my $iRiff = 0;
        while($dataOffset < length($dataContents))
        {
            print "dataOffset: $dataOffset\n";

            my ($riffHeader, $riffLength) = unpack("A4L<", substr($dataContents, $dataOffset, $riffHeaderLength));
            print "riffHeader: $riffHeader\n";
            print "riffLength: $riffLength\n";

            my $riffData = substr($dataContents, $dataOffset, $riffHeaderLength + $riffLength);
            my $wavFilename = "${bnkFilename}-${iRiff}.wav";
            open WAV_FILE, ">${wavFilename}";
            binmode WAV_FILE;
            print length($riffData) ."\n";
            print WAV_FILE $riffData;
            close WAV_FILE;

            system("${ww2ogg} --full-setup ${wavFilename}");

            unlink $wavFilename;

            $dataOffset += $riffHeaderLength + $riffLength;

            my $pad = 0;
            if($dataOffset % 16 != 0)
            {
                $pad = 16 - ($dataOffset % 16);
            }

            $dataOffset += $pad;

            print "pad: $pad\n";

            $iRiff++;
        }
    }
}