src.pro

#-------------------------------------------------
#
# Project created by QtCreator 2021-08-20T00:08:51
#
#-------------------------------------------------

QT          += core gui sql widgets

TARGET      =  RedHRM
TEMPLATE    =  app
VERSION     =  0.2

QMAKE_INFO_PLIST    = resources/Info.plist

i18n_app.target     =   resources/i18n/app_fr.qm
i18n_app.commands   =   $$[QT_INSTALL_BINS]/lrelease $$PWD/src.pro

i18n_qt.target      =   $$PWD/resources/i18n/qt_fr.qm
i18n_qt.commands    =   $$[QT_INSTALL_BINS]/lconvert -o $$PWD/resources/i18n/qt_fr.qm $$[QT_INSTALL_TRANSLATIONS]/qtbase_fr.qm

PRE_TARGETDEPS      +=  i18n_app \
                        i18n_qt
QMAKE_EXTRA_TARGETS +=  i18n_app \
                        i18n_qt

SOURCES     += main.cpp \
               Admin/AdminMenuWidget.cpp \
               Admin/CheckboxItemDelegate.cpp \
               Admin/StoresWidget.cpp \
               Application.cpp \
               Admin/DesignerWidget.cpp \
               MainWindow.cpp \
               Admin/SettingsDialog.cpp \
               MenuWidget.cpp \
               Models/RelationalTableModel.cpp \
               Models/Table.cpp \
               User/ProductsWidget.cpp \
               User/StocksDialog.cpp

HEADERS     += MainWindow.hpp \
               Admin/AdminMenuWidget.hpp \
               Admin/CheckboxItemDelegate.hpp \
               Admin/StoresWidget.hpp \
               Application.hpp \
               Admin/DesignerWidget.hpp \
               Admin/SettingsDialog.hpp \
               MenuWidget.hpp \
               Models/RelationalTableModel.hpp \
               Models/Table.hpp \
               User/ProductsWidget.hpp \
               User/StocksDialog.hpp

RESOURCES   += res.qrc

TRANSLATIONS = resources/i18n/app_fr.ts

DISTFILES   += resources/3992931_hotel_architect_architecture_building_icon.svg \
               resources/i18n/app_fr.ts \
               resources/Info.plist \
               resources/migrations/2108270000_create_migrations_table.sql \
               resources/migrations/2108280001_create_admins_table.sql \
               resources/migrations/2108280002_insert_admins.sql \
               resources/migrations/2108280003_create_users_table.sql \
               resources/migrations/2108280004_create_stores_table.sql \
               resources/migrations/2108291842_create_products_table.sql \
               resources/migrations/2108300315_insert_default_user.sql \
               resources/migrations/2109010124_insert_loss_store.sql \
               resources/migrations/2109010130_create_products_stores_table.sql

QMAKE_CLEAN +=  resources/i18n/app_fr.qm \
                resources/i18n/qt_fr.qm